Use dfdbmdpn.pkg
Use Windows.pkg

Cd_Popup_Object oShell_Extentions is a dbModalPanel

    Set Label to "Shell extentions"
    Set Location to 28 96
    // Visual DataFlex 14.0 Client Size Adjuster, modified May 7, 2008: 13:11:33
//    Set Size to 144 217
    Set Size to 126 211
    Set Border_Style to Border_Dialog

    Object oBox is a Container3d
        Set Size to 61 202
        Set Location to 4 5
        Object Textbox1 is a Textbox
            Set Label to "Associate the following filetypes with AnyFlex."
            Set FontSize to 4 0
            Set Location to 8 27
            Set Size to 10 149
            Set Justification_Mode to jMode_Left
            Set TypeFace to "MS Sans Serif"
        End_Object    // Textbox1

        Object chkDat is a CheckBox
            Set Label to ".DAT (DATAFLEX file)"
            Set Size to 10 101
            Set Location to 23 49

            Set checked_state to True

            Procedure OnChange
                Boolean bChecked
                Forward Send OnChange
                Get checked_state to bChecked
                If (bChecked = False) Set checked_state of oChkNew to False
                Set enabled_state of oChkNew to bChecked
            End_Procedure


        End_Object    // chkDat

        Object chkINT is a CheckBox
            Set Label to ".INT (Driverbased file)"
            Set Size to 10 109
            Set Location to 41 49

            Set checked_state to True
            //Set enabled_state To False
            //Set visible_state To False


        End_Object    // chkINT

    End_Object    // oBox

    Object oBox2 is a Container3d
        Set Size to 34 202
        Set Location to 66 5
        Object oChkNew is a CheckBox
            Set Label to "Add to New context menu."
            Set Size to 10 101
            Set Location to 9 15


            Set checked_state to True

            Procedure OnChange
                Boolean bChecked

                Get Checked_State to bChecked
            End_Procedure // OnChange

        End_Object    // oChkNew





    End_Object    // oBox2

    Object oOK_bn is a Button
        Set Label to "&Ok"
        Set Location to 107 103


        Procedure OnClick
            Integer iDat iInt
            String sCommand sVDFroot sFil sDir sPrg sDefaultIcon
            Boolean bNew
            Get checked_state of chkDat to iDat
            Get checked_state of chkInt to iInt
            Get checked_state of oChkNew to bNew
            Get GetApplicationFileName of oApplication to sPrg
            Move (C34 + sPrg + C34) to sCommand
            Append sCommand " " C34 "%1" C34
            Move (ToAnsi(sCommand)) to sCommand
            Move (sPrg + ",0") to sDefaultIcon

            If iDat Begin
                Send WriteGlobalReg HKEY_CLASSES_ROOT ".DAT" "" "DATfile"
                Send WriteGlobalReg HKEY_CLASSES_ROOT "DATfile" "" "Database-file"
                Send WriteGlobalReg HKEY_CLASSES_ROOT "DATfile\Shell\open\command" "" sCommand
                Send WriteGlobalReg HKEY_CLASSES_ROOT "DATfile\DefaultIcon" "" sDefaultIcon
            End
            Else Begin
                Send DeleteGlobalReg HKEY_CLASSES_ROOT ".DAT"
            End

            If iInt Begin
                Send WriteGlobalReg HKEY_CLASSES_ROOT ".INT" "" "INTfile"
                Send WriteGlobalReg HKEY_CLASSES_ROOT "INTfile" "" "Driverbased Database-file"
                Send WriteGlobalReg HKEY_CLASSES_ROOT "INTfile\Shell\open\command" "" sCommand
                Send WriteGlobalReg HKEY_CLASSES_ROOT "INTfile\DefaultIcon" "" sDefaultIcon
            End
            Else Begin
                Send DeleteGlobalReg HKEY_CLASSES_ROOT ".INT"
            End

            If bNew Begin
                Send WriteGlobalReg HKEY_CLASSES_ROOT ".DAT\DATfile\ShellNew" "Command" (sCommand+" NEW")
            End
            Else Begin
                Send DeleteGlobalReg HKEY_CLASSES_ROOT ".DAT\DATfile\ShellNew" "Command"
            End
            Send Request_Cancel

        End_Procedure

    End_Object    // oOK_bn

    Object oAnnuller_bn is a Button
        Set Label to "&Cancel"
        Set Location to 107 157


        Procedure OnClick
            Send Request_cancel
        End_Procedure

    End_Object    // oAnnuller_bn


    On_Key Key_Alt+Key_O Send KeyAction to oOk_bn
    On_Key Key_Alt+Key_C Send KeyAction to oAnnuller_bn

Cd_End_Object    // oShell_Extentions