Use cCJGridColumn.pkg
Use cCJGrid.pkg

Class cDataColumn is a cCJGridColumn
    
    Procedure Construct_Object
        Forward Send Construct_Object
        Property Integer piDefinedColumns -1
    End_Procedure
    
    
    Procedure OnSetDisplayMetrics Handle hoGridItemMetrics Integer iRow String  ByRef sValue
        Handle hoDataSource
        tDataSourceRow[] lsData
        Integer iColumnID iDefinedColumns
        Forward Send OnSetDisplayMetrics hoGridItemMetrics iRow (&sValue)
        Get phoDataSource to hoDataSource
        Get DataSource of hoDataSource to lsData
        Get piColumnId to iColumnID
        If (lsData[iRow].vTag =< iColumnID) Begin
            Set ComBackColor of hoGridItemMetrics to clLtGray
        End
        Else Begin
            Get piDefinedColumns to iDefinedColumns
            If (iDefinedColumns <> lsData[iRow].vTag and iDefinedColumns <> -1) Begin
                Set ComBackColor of hoGridItemMetrics to 11193087
            End
        End
    End_Procedure


    Function OnGetTooltip Integer iRow String sValue String sText Returns String
        String sRetVal
        Handle hoDataSource
        tDataSourceRow[] lsData
        Integer iColumnID iDefinedColumns
        Forward Get OnGetTooltip iRow sValue sText to sRetVal
        Get phoDataSource to hoDataSource
        Get DataSource of hoDataSource to lsData
        Get piDefinedColumns to iDefinedColumns
        If (iDefinedColumns <> lsData[iRow].vTag and iDefinedColumns <> -1) Begin
            Move (SFormat("Read error. Columns read: %1, Defined columns: %2", lsData[iRow].vTag, iDefinedColumns)) to sRetVal
        End
        Function_Return sRetVal
    End_Function
    
    
    
End_Class