Use Windows.pkg

Object oRecordCount is a ModalPanel
    Set Size to 89 211
    Set Label to "Record count"
    Set piMinSize to 89 211
    Set Location to 15 14
    Set Border_Style To Border_Thick
    
    Property Boolean pbReload

    Object oClose_Btn is a Button
        Set Label    to "&Close"
        Set Location to 71 153
        Set peAnchors to anBottomRight

        Procedure OnClick
            Send Close_Panel
        End_Procedure

    End_Object

    Object oRecordsUsed is a Form
        Set Size to 13 100
        Set Location to 16 83
        Set Label to "Records used:"
        Set Enabled_State to False

        Procedure Activating
            Integer iFile iRecordsUsed
            Forward Send Activating
            Get piFilenumber to iFile
            If (iFile <> 0) Begin
                Get_Attribute DF_FILE_RECORDS_USED of iFile to iRecordsUsed
                Set value to iRecordsUsed
            End
        End_Procedure
    
    End_Object

    Object oMaxRecords is a Form
        Set Size to 13 100
        Set Location to 39 83
        Set Label to "Max. records:"

        Procedure Activating
            Integer iFile iMaxRecord
            String sDriver
            Boolean bEnabled
            Forward Send Activating
            Move False to bEnabled
            Get piFilenumber to iFile
            If (iFile <> 0) Begin
                Get psCurrentDriver to sDriver
                If (sDriver = "DATAFLEX") Begin
                    Get_Attribute DF_FILE_MAX_RECORDS of iFile to iMaxRecord
                    Set Value to iMaxRecord
                    Move True to bEnabled
                End
                Else Begin
                    Set Value to "(na)"
                End
            End
            Set Enabled_State to bEnabled
        End_Procedure
        
           
       Procedure DoRetFilesize
            String sValgtFil
            Integer iNyMaxRec StructHandle iFile iFile2

            Get piFileNumber to iFile2

            Get psFilename to sValgtFil
            If (sValgtFil = "") Procedure_Return

            Get NextFreeFilenumber iFile2 to iFile
            If (iFile = 0) Procedure_Return

            Get value to iNyMaxRec

            Send DoCloseAllFiles

            Open sValgtFil as iFile Mode DF_EXCLUSIVE
            If (Found) Begin
                Send DoStartResInfo of oResInfo
                Move iFile to StructHandle
                Structure_Start StructHandle
                    Set_Attribute DF_FILE_MAX_RECORDS of StructHandle to iNyMaxRec
                Structure_End StructHandle DF_STRUCTEND_OPT_NONE "" (oResInfo(Self))
                Send DoStopResInfo of oResInfo
            End
            Close iFile
            
            Send Info_Box "Max. records changed."

            Set pbReload to True

       End_Procedure
    
       On_Key key_F2 Send DoRetFilesize
    
    End_Object

    On_Key Key_Alt+Key_C Send KeyAction of oClose_Btn
    
    Function DoShowCount Returns Boolean
        Boolean bReload
        Set pbReload to False
        Send Popup
        Get pbReload to bReload
        Function_Return bReload
    End_Function

End_Object