//AB/ Project Change Password
//AB/ Object oIDE_Project is a Dialog_Project
  //AB/ Set ProjectName to "Change Password"
  //AB/ Set ProjectFileName to "ChangePassword.DG"
  //AB/ Set GenerateFileName to "NONAME5"
  //AB/ Set Size to 149 262

// Project Object Structure
//   oChangePassword_dg is a ModalPanel
//     oBitmap is a cRDSBitmapContainer
//     oNewPV_fm is a cRDSForm
//     oConfirmPV_fm is a cRDSForm
//     oTest_bn is a cRDSButton
//     oOK_bn is a Button
//     oCancel_bn is a Button

// Register all objects
Register_Object oBitmap
Register_Object oCancel_bn
Register_Object oChangePassword_dg
Register_Object oConfirmPV_fm
Register_Object oNewPV_fm
Register_Object oOK_bn
Register_Object oTest_bn


//AB-StoreTopStart
Use cCrypt.pkg
Use Working.pkg
//AB-StoreTopEnd

//AB-IgnoreStart
Use Windows.pkg
Use cRDSBitmapContainer.pkg
Use cRDSForm.pkg
Use cRDSButton.pkg
//AB-IgnoreEnd



Object oChangePassword_dg is a ModalPanel

  //AB-StoreTopStart
  Property Handle phoDD 0
  Property Boolean pbFrom True
  //AB-StoreTopEnd

  Set Icon to "RdsText.ico"
  Set Label to "Change Password"
  Set Location to 8 16
  Set Size to 104 217
  Set piMinSize to 104 217

  //AB-DDOStart


  //AB-DDOEnd

  Object oBitmap is a cRDSBitmapContainer
    Set Size to 26 36
    Set Location to 2 5
    Set Bitmap to "Keys32.bmp"
    Set Border_Style to Border_None
    Set Dialog_Caption to ""
  End_Object    // oBitmap

  Object oNewPV_fm is a cRDSForm
    Set Label to "New Password:"
    Set Size to 13 85
    Set Location to 15 98
    Set Label_Col_Offset to 2
    Set Label_Justification_Mode to jMode_Right

    //AB-StoreStart
    Set Password_State item 0 To True
    
    Procedure OnChange
      Handle ho
      Move (Parent(Self)) To ho
      Broadcast Send DoEnableDisable Of ho
    End_Procedure  // OnChange
    //AB-StoreEnd

  End_Object    // oNewPV_fm

  Object oConfirmPV_fm is a cRDSForm
    Set Label to "Confirm Password:"
    Set Size to 13 85
    Set Location to 30 98
    Set Label_Col_Offset to 2
    Set Label_Justification_Mode to jMode_Right

    //AB-StoreStart
    Set Password_State item 0 To True
    
    Procedure OnChange
      Handle ho
      Move (Parent(Self)) To ho
      Broadcast Send DoEnableDisable Of ho
    End_Procedure  // OnChange
    //AB-StoreEnd

  End_Object    // oConfirmPV_fm

  Object oTest_bn is a cRDSButton
    Set Label to "&Test Login"
    Set Location to 50 98

    //AB-StoreStart
    Procedure OnClick
      String sServer sUser sPassword sDriver sOwner
      Integer iFile
      Boolean bFrom bIsOpen
      Handle hoDD
    
      Send StartWorkingMessage "Trying to connect to database server..."
      Send Ignore_Error Of Error_Info_Object   75  // 'Can't open data file'
      Send Ignore_Error Of Error_Info_Object 12293 // 'Data source name not found'
      Send Ignore_Error Of Error_Info_Object 12295 // 'Table not in connection'
    
      Delegate Get phoDD            To hoDD
      Delegate Get pbFrom           To bFrom
      Get Value Of oNewPV_fm item 0 To sPassword
    
      If bFrom Begin
        Get Field_Current_Value Of hoDD Field SncTable.FromFile   To iFile
        Get Field_Current_Value Of hoDD Field SncTable.Fromdriver To sDriver
        Get Field_Current_Value Of hoDD Field SncTable.FromServer To sServer
        Get Field_Current_Value Of hoDD Field SncTable.FromOwner  To sOwner
        Get Field_Current_Value Of hoDD Field SncTable.FromUser   To sUser
      End // If bFrom Begin
      Else Begin
        Get Field_Current_Value Of hoDD Field SncTable.ToFile     To iFile
        Get Field_Current_Value Of hoDD Field SncTable.Todriver   To sDriver
        Get Field_Current_Value Of hoDD Field SncTable.ToServer   To sServer
        Get Field_Current_Value Of hoDD Field SncTable.ToOwner    To sOwner
        Get Field_Current_Value Of hoDD Field SncTable.ToUser     To sUser
      End // Else Begin
    
      Move (Trim(sDriver)) To sDriver
      Move (Trim(sServer)) To sServer
      Move (Trim(sOwner))  To sOwner
      Move (Trim(sUser))   To sUser
    
      If (iFile = 0 Or Length(sDriver) = 0) Begin
        Send Stop_Box "No Database Table specified or Driver name is invalid"
        Send StopWorkingMessage
        Procedure_Return
      End // If (iFile = 0 Or Length(sDriver) = 0) Begin
    
      If (Uppercase(sDriver) <> DB2_DRV_ID) Begin
        Logout sDriver sServer
        Get_Attribute DF_FILE_OPENED Of iFile To bIsOpen
        If bIsOpen Set_Attribute DF_FILE_OWNER Of iFile To sOwner
      End // If (Uppercase(sDriver) <> DB2_DRV_ID) Begin
    
      If (Uppercase(sDriver) <> DFBTRDRV_ID) Begin
        DFBTR_REMOVE_ALL_OWNERS
        DFBTR_ADD_OWNER sPassword
        Move "" To sPassword
      End // If (Uppercase(sDriver) <> DFBTRDRV_ID) Begin
    
      Indicate Err False  // Will be set by the Login command.
      Login sServer sUser sPassword sDriver
      Send StopWorkingMessage
      If (Err) Send Info_Box "Login unsuccessful. Please try again."
      Else     Send Info_Box "Login successful."
      Get_Attribute DF_FILE_OPENED Of iFile To bIsOpen
      If Not bIsOpen Begin
        Open iFile
        If Not (Found) Send Info_Box "Warning! Could not re-open the data table."
      End // If Not bIsOpen Begin
      Send Trap_Error Of Error_Info_Object    75
      Send Trap_Error Of Error_Info_Object 12293
      Send Trap_Error Of Error_Info_Object 12295
    End_Procedure // OnClick
    
    Procedure DoEnableDisable
      String sNew sConfirm
      Get Value Of oNewPV_fm     item 0 To sNew
      Get Value Of oConfirmPV_fm item 0 To sConfirm
      Move (Trim(sNew))                 To sNew
      Move (Trim(sConfirm))             To sConfirm
      Set Enabled_State To (Length(sNew) > 0 And sNew = sConfirm)
    End_Procedure // DoEnableDisable
    //AB-StoreEnd

  End_Object    // oTest_bn

  Object oOK_bn is a Button
    Set Label to "&OK"
    Set Location to 71 98
    Set peAnchors to anBottomRight
    Set Default_State to TRUE

    //AB-StoreStart
    Procedure OnClick
      Handle hoDD
      String sNew
      Boolean bFrom
      Delegate Get phoDD  To hoDD           // Panel property.
      Delegate Get pbFrom To bFrom          // Panel property.
      Get Value Of oNewPV_fm item 0 To sNew
      Get CmEnKry sNew              To sNew
      If bFrom Set Field_Changed_Value Of hoDD Field SncTable.FromPV To sNew
      Else     Set Field_Changed_Value Of hoDD Field SncTable.ToPV   To sNew
      Send Close_Panel
    End_Procedure // OnClick
    
    Procedure DoEnableDisable
      String sNew sConfirm
      Get Value Of oNewPV_fm     item 0 To sNew
      Get Value Of oConfirmPV_fm item 0 To sConfirm
      Move (Trim(sNew))                 To sNew
      Move (Trim(sConfirm))             To sConfirm
      Set Enabled_State To (Length(sNew) > 0 And sNew = sConfirm)
      Set Default_State To (Length(sNew) > 0 And sNew = sConfirm)
    End_Procedure // DoEnableDisable
    //AB-StoreEnd

  End_Object    // oOK_bn

  Object oCancel_bn is a Button
    Set Label to "&Cancel"
    Set Location to 71 157
    Set peAnchors to anBottomRight

    //AB-StoreStart
    Procedure OnClick
      Send Close_Panel
    End_Procedure // OnClick
    //AB-StoreEnd

  End_Object    // oCancel_bn


  //AB-StoreStart
  Set Locate_Mode To Center_On_Screen
  
  Procedure DoPopupChangePassword Handle hoDD Boolean bFrom
    Set phoDD  To hoDD
    Set pbFrom To bFrom
    Set Value  Of oNewPV_fm     To ""
    Set Value  Of oConfirmPV_fm To ""
    Send Popup
  End_Procedure // DoPopupChangePassword
  
  On_Key Key_Alt+Key_O Send KeyAction Of oOK_bn
  On_Key Key_Alt+Key_C Send KeyAction Of oCancel_bn
  On_Key kCancel       Send KeyAction Of oCancel_bn
  On_Key Key_Alt+Key_T Send KeyAction Of oTest_bn
  
  //AB-StoreEnd

End_Object    // oChangePassword_dg


//AB-StoreStart
Procedure DoPopupChangePassword Handle hoDD Boolean bFrom
  Send DoPopupChangePassword Of oChangePassword_dg hoDD bFrom
End_Procedure // DoPopupChangePassword

//AB-StoreEnd

//AB/ End_Object    // oIDE_Project