//AB/ Project Properties dialog
//AB/ Object prj is a Dialog_Project
  //AB/ Set ProjectName to "Properties dialog"
  //AB/ Set ProjectFileName to "Properties.DG"
  //AB/ Set Size to 149 301

// Project Object Structure
//   oProperties_dg is a cRDSDbModalPanel
//     Sncsys_DD is a DataDictionary
//     oTableRowColor_fm is a cRDSForm
//     oTableRowColor_bn is a cBitmapButton
//     oTableCellColor_fm is a cRDSForm
//     oTableCellColor_bn is a cBitmapButton
//     oUseToolTip_cb is a cRDSCheckBox
//     oDebug_cb is a cRDSCheckBox
//     oSncsys_Uselogin is a cSysDbCheckBox
//     oName_fm is a cRDSForm
//     oPassword_fm is a cRDSForm
//     oColorDialog is a ColorDialog
//     oApply_bn is a cBitmapButton
//     oClose_bn is a cBitmapButton

// Register all objects
Register_Object oApply_bn
Register_Object oClose_bn
Register_Object oColorDialog
Register_Object oDebug_cb
Register_Object oName_fm
Register_Object oPassword_fm
Register_Object oProperties_dg
Register_Object oSncsys_Uselogin
Register_Object oTableCellColor_bn
Register_Object oTableCellColor_fm
Register_Object oTableRowColor_bn
Register_Object oTableRowColor_fm
Register_Object oUseToolTip_cb
Register_Object Sncsys_DD


//AB-StoreTopStart
Use cToolbar.pkg

Procedure DoPopupProperties
  Handle hoMain
  Boolean bOldState bNewState
  Get ReadDWord Of ghoApplication "Preferences" "pbToolTips" 0      To bOldState
  Send Popup Of oProperties_dg
  Get ReadDWord Of ghoApplication "Preferences" "pbToolTips" 0      To bNewState
  If (bOldState <> bNewState) Begin
    Get phoMainPanel Of ghoApplication To hoMain
    Broadcast Recursive Set pbToolTips Of hoMain                    To bNewState
//    Send Activate Of (oSnctable_Recid(phoSDIView(ghoApplication)))
  End // If (bOldState <> bNewState) Begin
End_Procedure // DoPopupProperties
//AB-StoreTopEnd

//AB-IgnoreStart
Use cRDSDbModalPanel.pkg
Use DataDict.pkg
Use cRDSForm.pkg
Use cBitmapButton.pkg
Use cRDSCheckBox.pkg
Use cSysDbCheckBox.pkg
Use Colr_Dlg.Pkg
//AB-IgnoreEnd


//AB-IgnoreStart
Use SNCSYS.DD
//AB-IgnoreEnd


Object oProperties_dg is a cRDSDbModalPanel
  Set Minimize_Icon to FALSE
  Set Label to "Program Properties"
  Set Location to 1 1
  Set Size to 127 283

  //AB-DDOStart

  Object Sncsys_DD is a Sncsys_DataDictionary
  End_Object    // Sncsys_DD

  Set Main_DD to Sncsys_DD
  Set Server to Sncsys_DD

  //AB-DDOEnd

  Object oTableRowColor_fm is a cRDSForm

    //AB-StoreTopStart
    Property String psKey "Preferences"
    Property String psVal "CurrentRowColor"
    Property Integer piColor 0
    //AB-StoreTopEnd

    Set Label to "Table row color:"
    Set Size to 13 90
    Set Location to 7 66
    Set Status_Help to "Press F4 or Alt+S to display the Color Selection Dialog"
    Set Label_Col_Offset to 2
    Set Label_Justification_Mode to jMode_Right

    //AB-StoreStart
    Set Entry_State Item 0 To False
    
    Procedure DoWriteRegistryKey
      Integer iNewKey iOldKey
      Get piColor To iNewKey
      Get ReadDWord Of ghoApplication (psKey(Self)) (psVal(Self)) 0 To iOldKey
      If (iNewKey <> iOldKey) ;
        Send WriteDWord Of ghoApplication (psKey(Self)) (psVal(Self))  iNewKey
    End_Procedure // DoWriteRegistryKey
    
    Procedure DoApplyRegistryKey
      Handle hoMain
      Integer iColor
      Get phoSDIView Of ghoApplication To hoMain
      Get ReadDWord Of ghoApplication (psKey(Self)) (psVal(Self)) 0 To iColor
      If Not iColor Begin
        Move clAqua To iColor
        Send WriteDWord Of ghoApplication (psKey(Self)) (psVal(Self))  iColor
      End // If Not iColor Begin
      Set piColor   To iColor
      Set Color     To iColor
      Set TextColor To iColor
      If hoMain Broadcast Recursive Set CurrentRowColor Of hoMain   To iColor
    End_Procedure // DoApplyRegistryKey
    
    Procedure Prompt
      Send KeyAction Of (oTableRowColor_bn(Self))
    End_Procedure // Prompt
    
    //Procedure Set pbToolTips Boolean bState
    //End_Procedure // Set pbToolTips
    
    Send DoApplyRegistryKey // Do on program startup.
    On_Key kPrompt Send Prompt
    
    //AB-StoreEnd

  End_Object    // oTableRowColor_fm

  Object oTableRowColor_bn is a cBitmapButton
    Set Label to "&Select color"
    Set Size to 15 66
    Set Location to 5 158
    Set Status_Help to "Click to display Color dialog"
    Set Bitmap to "Colors16.bmp"
    Set piTransparentColor to clWhite

    //AB-StoreStart
    Procedure OnClick
      Integer ho iOldColor iNewColor
      Move (oTableRowColor_fm(Self)) To ho
      Get piColor         Of ho To iOldColor
      Set SelectedColor   Of oColorDialog To iOldColor
      Get SelectColor     Of oColorDialog To iNewColor
      If (iOldColor <> iNewColor And iNewColor <> -1) Begin
        Set piColor       Of ho To iNewColor
        Set Color         Of ho To iNewColor
        Set TextColor     Of ho To iNewColor
        Set Enabled_State Of oApply_bn To True
      End // If (iOldColor <> iNewColor) Begin
    End_Procedure // OnClick
    
    //Procedure Set pbToolTips Boolean bState
    //End_Procedure // Set pbToolTips
    
    //AB-StoreEnd

  End_Object    // oTableRowColor_bn

  Object oTableCellColor_fm is a cRDSForm

    //AB-StoreTopStart
    Property String psKey "Preferences"
    Property String psVal "CurrentCellColor"
    Property Integer piColor 0
    //AB-StoreTopEnd

    Set Label to "Table cell color:"
    Set Size to 13 90
    Set Location to 22 66
    Set Status_Help to "Press F4 or Alt+S to display the Color Selection Dialog"
    Set Label_Col_Offset to 2
    Set Label_Justification_Mode to jMode_Right

    //AB-StoreStart
    Set Entry_State Item 0 To False
    
    Procedure DoWriteRegistryKey
      Integer iNewKey iOldKey
      Get piColor To iNewKey
      Get ReadDWord Of ghoApplication (psKey(Self)) (psVal(Self)) 0 To iOldKey
      If (iNewKey <> iOldKey) ;
        Send WriteDWord Of ghoApplication (psKey(Self)) (psVal(Self))  iNewKey
    End_Procedure // DoWriteRegistryKey
    
    Procedure DoApplyRegistryKey
      Handle hoMain
      Integer iColor
      Get phoSDIView Of ghoApplication                              To hoMain
      Get ReadDWord Of ghoApplication (psKey(Self)) (psVal(Self)) 0 To iColor
      If Not iColor Begin
        Move clYellow                                               To iColor
        Send WriteDWord Of ghoApplication (psKey(Self)) (psVal(Self))  iColor
      End // If Not iColor Begin
      Set piColor                                                   To iColor
      Set Color                                                     To iColor
      Set TextColor                                                 To iColor
      If hoMain Broadcast Recursive Set CurrentCellColor Of hoMain  To iColor
    End_Procedure // DoApplyRegistryKey
    
    Procedure Prompt
      Send KeyAction Of (oTableCellColor_bn(Self))
    End_Procedure // Prompt
    
    //Procedure Set pbToolTips Boolean bState
    //End_Procedure // Set pbToolTips
    
    Send DoApplyRegistryKey // Do on program startup.
    On_Key kPrompt Send Prompt
    
    //AB-StoreEnd

  End_Object    // oTableCellColor_fm

  Object oTableCellColor_bn is a cBitmapButton
    Set Label to "S&elect color"
    Set Size to 15 66
    Set Location to 22 158
    Set Status_Help to "Click to display Color dialog"
    Set Bitmap to "Colors16.bmp"
    Set piTransparentColor to clWhite

    //AB-StoreStart
    Procedure OnClick
      Integer ho iOldColor iNewColor
      Move (oTableCellColor_fm(Self)) To ho
      Get piColor         Of ho To iOldColor
      Set SelectedColor   Of oColorDialog To iOldColor
      Get SelectColor     Of oColorDialog To iNewColor
      If (iOldColor <> iNewColor And iNewColor <> -1) Begin
        Set piColor       Of ho To iNewColor
        Set Color         Of ho To iNewColor
        Set TextColor     Of ho To iNewColor
        Set Enabled_State Of oApply_bn To True
      End // If (iOldColor <> iNewColor) Begin
    End_Procedure // OnClick
    
    //Procedure Set pbToolTips Boolean bState
    //End_Procedure // Set pbToolTips
    
    //AB-StoreEnd

  End_Object    // oTableCellColor_bn

  Object oUseToolTip_cb is a cRDSCheckBox

    //AB-StoreTopStart
    Property String psKey "Preferences"
    Property String psVal "pbToolTips"
    Property Boolean pbStartUp True
    //AB-StoreTopEnd

    Set Label to "Use tooltip hints"
    Set Size to 10 67
    Set Location to 37 66
    Set Status_Help to "Display tooltip help when hoovering the mouse over an object. (The text you are seeing now.)"

    //AB-StoreStart
    Procedure OnChange
      Boolean bState bChecked
      Get Checked_State To bChecked
      Get ReadDWord Of ghoApplication (psKey(Self)) (psVal(Self)) 0  To bState
      If (Active_State(Self) And bChecked <> bState) Begin
        Set Enabled_State Of oApply_bn  To True
        If Not (pbStartUp(Self)) Broadcast Recursive Set pbToolTips Of (Parent(Self)) To bChecked
      End // If (Active_State(Self) And bChecked <> bState) Begin
    End_Procedure // OnChange
    
    Procedure DoWriteRegistryKey
      Boolean bState bChecked
      Get Checked_State To bChecked
      Get ReadDWord Of ghoApplication (psKey(Self)) (psVal(Self)) 0 To bState
      If (bChecked <> bState) Begin
        Send WriteDWord Of ghoApplication (psKey(Self)) (psVal(Self)) bChecked
      End // If (bChecked <> bState) Begin
    End_Procedure // DoWriteRegistryKey
    
    Procedure DoApplyRegistryKey
      Handle hoReg hoToolTip
      Boolean bState bExist bFirst
      String sKey
      Get RegistryKeyString Of ghoApplication To sKey
      Move (sKey + "\" + psKey(Self))         To sKey
      Get Create U_cRegistry                  To hoReg
      Get ValueExists     Of ghoApplication (psKey(Self)) (psVal(Self))    To bExist
      If bExist ;
        Get ReadDWord     Of ghoApplication (psKey(Self)) (psVal(Self)) -1 To bState
      If Not bExist Begin
        Move (True)                                                        To bState
        Send WriteDWord   Of ghoApplication (psKey(Self)) (psVal(Self))       bState
      End // If Not bExist Begin
      Send Destroy Of hoReg
      Set Checked_State                                                    To bState
    End_Procedure // DoApplyRegistryKey
    Send DoApplyRegistryKey // Do on program startup.
    Set pbStartUp To False
    
    //Procedure Set pbToolTips Boolean bState
    //End_Procedure // Set pbToolTips
    
    //AB-StoreEnd

  End_Object    // oUseToolTip_cb

  Object oDebug_cb is a cRDSCheckBox

    //AB-StoreTopStart
    Property String psKey "Preferences"
    Property String psVal "pbDebugMode"
    //AB-StoreTopEnd

    Set Label to "Debug Mode"
    Set Size to 10 58
    Set Location to 48 66
    Set Status_Help to "If an error occur display the error message with a status number and the source line number. Use this when you want to report a program bug."

    //AB-StoreStart
    //Set Status_Help To "If an error occur display the error message with a status number and the source line number. Use this when you want to report a program bug."
    
    Procedure OnChange
      Boolean bState bChecked
      Get Checked_State To bChecked
      Get ReadDWord Of ghoApplication (psKey(Self)) (psVal(Self)) 0 To bState
      If (Active_State(Self) And bChecked <> bState) Set Enabled_State Of oApply_bn To True
    End_Procedure // OnChange
    
    Procedure DoWriteRegistryKey
      Boolean bState bChecked
      Get Checked_State To bChecked
      Get ReadDWord Of ghoApplication (psKey(Self)) (psVal(Self)) 0 To bState
      If (bChecked <> bState) ;
        Send WriteDWord Of ghoApplication (psKey(Self)) (psVal(Self)) bChecked
    End_Procedure // DoWriteRegistryKey
    
    Procedure DoApplyRegistryKey
      Handle hoReg hoToolTip
      Boolean bState bExist
      String sKey
      Get RegistryKeyString Of ghoApplication To sKey
      Move (sKey + "\" + psKey(Self))         To sKey
      Get Create U_cRegistry                  To hoReg
      Get ValueExists       Of ghoApplication (psKey(Self)) (psVal(Self))    To bExist
      If bExist
        Get ReadDWord       Of ghoApplication (psKey(Self)) (psVal(Self)) -2 To bState
      If Not bExist Begin
        Move (False)                                                         To bState
        Send WriteDWord     Of ghoApplication (psKey(Self)) (psVal(Self))       bState
      End // If Not bExist Begin
      Send Destroy Of hoReg
      Set Checked_State                                                      To bState
      Set Verbose_State Of Error_Info_Object                                 To bState
    //  Get Private.phoToolTip                  To hoToolTip
    //  If hoToolTip Send Destroy Of hoToolTip
    End_Procedure // DoApplyRegistryKey
    Send DoApplyRegistryKey // Do on program startup.
    
    //Procedure Set pbToolTips Boolean bState
    //End_Procedure // Set pbToolTips
    
    //AB-StoreEnd

  End_Object    // oDebug_cb

  Object oSncsys_Uselogin is a cSysDbCheckBox
    Entry_Item Sncsys.Uselogin
    Set Label to "Use Login for this program"
    Set Size to 10 99
    Set Location to 59 66

    //AB-StoreStart
    Procedure OnChange
      Boolean bChecked bChanged
      If (Active_State(Self)) Begin
        Get Changed_State       Of Sncsys_DD To bChanged
        Get Field_Current_Value Of Sncsys_DD Field SncSys.UseLogin To bChecked
        Set Enabled_State       Of oName_fm        To bChecked
        Set Enabled_State       Of oPassword_fm    To bChecked
        If bChanged Set Enabled_State Of oApply_bn To True
      End // If (Active_State(Self)) Begin
    End_Procedure // OnChange
    
    //Procedure Set pbToolTips Boolean bState
    //End_Procedure // Set pbToolTips
    
    //AB-StoreEnd

  End_Object    // oSncsys_Uselogin

  Object oName_fm is a cRDSForm
    Set Label to "Name:"
    Set Size to 13 90
    Set Location to 73 66
    Set Status_Help to "The user name to use when starting CrossMerge Builder."
    Set Label_Col_Offset to 2
    Set Label_Justification_Mode to jMode_Right

    //AB-StoreStart
    Set Enabled_State To SncSys.Uselogin
    //Set Status_Help   To "The user name to use when starting CrossMerge Builder"
    
    Procedure DoWriteRegistryKey
      String sValue
      Get Value Item 0 To sValue
      Set Field_Changed_Value Of Sncsys_DD Field SncSys.User To sValue
    End_Procedure // DoWriteRegistryKey
    
    Procedure OnChange
      Boolean bChanged
      If (Active_State(Self)) Begin
        Get Changed_State       Of Sncsys_DD To bChanged
        If bChanged Set Enabled_State Of oApply_bn To True
      End // If (Active_State(Self)) Begin
    End_Procedure // OnChange
    
    Procedure OnStartUp
      String sValue
      Get Field_Current_Value Of Sncsys_DD Field SncSys.User To sValue
      Set Value Item 0 To sValue
    End_Procedure // OnStartUp
    Send OnStartUp
    
    //Procedure Set pbToolTips Boolean bState
    //End_Procedure // Set pbToolTips
    
    //AB-StoreEnd

  End_Object    // oName_fm

  Object oPassword_fm is a cRDSForm
    Set Label to "Password:"
    Set Size to 13 90
    Set Location to 88 66
    Set Status_Help to "The password to use when starting CrossMerge Builder."
    Set Label_Col_Offset to 2
    Set Label_Justification_Mode to jMode_Right

    //AB-StoreStart
    Set Enabled_State         To SncSys.Uselogin
    Set Password_State Item 0 To True
    //Set Status_Help To "The password to use when starting CrossMerge Builder"
    
    Procedure DoWriteRegistryKey
      String sValue
      Get Value Item 0 To sValue
      Set Field_Changed_Value Of Sncsys_DD Field SncSys.Pv To sValue
    End_Procedure // DoWriteRegistryKey
    
    Procedure OnChange
      Boolean bChanged
      If (Active_State(Self)) Begin
        Get Changed_State       Of Sncsys_DD To bChanged
        If bChanged Set Enabled_State Of oApply_bn To True
      End // If (Active_State(Self)) Begin
    End_Procedure // OnChange
    
    //Function Next_Object_Id Returns Integer
    //  Handle ho
    //  Move (oTableRowColor_fm(Self)) To ho
    //  Function_Return ho
    //End_Function // Next_Object_Id
    
    Procedure OnStartUp
      String sValue
      Get Field_Current_Value Of Sncsys_DD Field SncSys.Pv To sValue
      Set Value Item 0 To sValue
    End_Procedure // OnStartUp
    Send OnStartUp
    
    //Procedure Set pbToolTips Boolean bState
    //End_Procedure // Set pbToolTips
    
    //AB-StoreEnd

  End_Object    // oPassword_fm

  Object oColorDialog is a ColorDialog
    //AB/ Set Location to 7 252

    //AB-StoreStart
    Function SelectColor Returns Integer
      Integer iRgbColor bColorSelected
      Get Show_Dialog To bColorSelected
      If (bColorSelected = True) Begin
        Get SelectedColor To iRgbColor
        Function_Return iRgbColor
      End
      Else Function_Return -1
    End_Function // SelectColor
    //AB-StoreEnd

  End_Object    // oColorDialog

  Object oApply_bn is a cBitmapButton
    Set Label to "&Apply"
    Set Size to 15 50
    Set Location to 85 166
    Set Status_Help to "Apply changes"
    Set Bitmap to "Ok16.bmp"
    Set piTransparentColor to clFuchsia

    //AB-StoreStart
    Set Enabled_State To False
    
    Procedure OnClick
      Handle ho
      Move (Parent(Self)) To ho
      Broadcast Send DoWriteRegistryKey Of ho
      Broadcast Send DoApplyRegistryKey Of ho
      Send Request_Save Of SncSys_DD
      Set Enabled_State To False
    End_Procedure // OnClick
    
    //Procedure Set pbToolTips Boolean bState
    //End_Procedure // Set pbToolTips
    
    //AB-StoreEnd

  End_Object    // oApply_bn

  Object oClose_bn is a cBitmapButton
    Set Label to "&Close"
    Set Size to 15 50
    Set Location to 85 219
    Set Status_Help to "Close panel. If you have made any changes, you need to press the 'Apply' button first."
    Set Bitmap to "Cancel16.bmp"
    Set piTransparentColor to clFuchsia

    //AB-StoreStart
    Procedure OnClick
      Send Close_Panel
    End_Procedure // OnClick
    
    //Procedure Set pbToolTips Boolean bState
    //End_Procedure // Set pbToolTips
    
    //AB-StoreEnd

  End_Object    // oClose_bn


  //AB-StoreStart
  Set Locate_Mode To CENTER_ON_SCREEN
  //Set Destroy_Object_State To True
  
  // We can't use ToolTips in modal panels, so destroy it.
  //Procedure OnStartup
  //  Handle hoHelp
  //  Get Private.phoToolTip Of (oSncsys_Uselogin(Self)) To hoHelp
  //  Send DestroyToolTip    Of hoHelp
  //End_Procedure // OnStartup
  //Send OnStartup
  
  On_Key Key_Alt+Key_S  Send KeyAction Of oTableRowColor_bn
  On_Key Key_Alt+Key_E  Send KeyAction Of oTableCellColor_bn
  On_Key Key_Alt+Key_A  Send KeyAction Of oApply_bn
  On_Key Key_Ctrl+Key_S Send KeyAction Of oApply_bn
  On_Key Key_Alt+Key_F2 Send KeyAction of oApply_bn
  On_Key Key_Alt+Key_C  Send KeyAction Of oClose_bn
  On_Key kCancel        Send KeyAction Of oClose_bn
  //AB-StoreEnd

End_Object    // oProperties_dg


//AB-StoreStart

//AB-StoreEnd

//AB/ End_Object    // prj