Use Windows
//Use DFMdlPnl
//StatPnl.pkg
// 2002-10-14 ------------------------------------ Start Nils G. Svedmyr
Use RDCSentDat.pkg
// 2002-10-14 ------------------------------------ Stop Nils G. Svedmyr

Enumeration_List
   Define Host_Data_Action
   Define Host_Data_Caption
   Define Host_Data_Title
   Define Host_Data_Message
   Define Host_Data_Button
   // 2002-10-14 ------------------------------------ Start Nils G. Svedmyr
   Define Host_Data_License
   // 2002-10-14 ------------------------------------ Stop Nils G. Svedmyr
   Define Host_Data_All
End_Enumeration_List

Class RDCSentinelPanel Is A ModalPanel

   Procedure Construct_Object
      Forward Send Construct_Object
      Property String  Button_text       Public "Cancel"
      Property String  Title_Text        Public ""
      Property String  Caption_Text      Public ""
      Property String  Message_Text      Public ""
      Property String  Action_Text       Public ""
      // 2002-10-14 ------------------------------------ Start Nils G. Svedmyr
      Property String  License_Text      Public ""
      // 2002-10-14 ------------------------------------ Stop Nils G. Svedmyr
   End_Procedure // Construct_Object

   Procedure Page Integer state
      local Integer hnd
      Forward Send Page state
      Get window_handle To hnd
      Set SentinelWindow To hnd
    End_Procedure

    Procedure Page_delete
       Set Sentinel_Return_Value To MSG_CANCEL
       Forward Send Page_delete
       Set SentinelWindow To 0
    End_Procedure // Page_delete

    Procedure OnSentinelDataChange Integer iBeg Integer iLength
        Integer Mode
        If iBeg Eq ACTIONSTART Begin
           Send Initialize_Action_Data
           Move HOST_DATA_ACTION To Mode
        End
        Else If iBeg Eq CAPTIONSTART Begin
           Send Initialize_Caption_Data
           Move HOST_DATA_CAPTION To Mode
        End
        Else If iBeg Eq TITLESTART Begin
           Send Initialize_Title_Data
           Move HOST_DATA_TITLE To Mode
        End
        Else If iBeg Eq MESSAGESTART Begin
           Send Initialize_Message_Data
           Move HOST_DATA_MESSAGE To Mode
        End
        Else If iBeg Eq BUTTONSTART Begin
           Send Initialize_Button_Data
           Move HOST_DATA_BUTTON To Mode
        End
        // 2002-10-14 ------------------------------------ Start Nils G. Svedmyr
        Else If iBeg Eq LICENSESTART Begin
           Send Initialize_License_Data
           Move HOST_DATA_LICENSE To Mode
        End
        // 2002-10-14 ------------------------------------ Stop Nils G. Svedmyr
        Else Begin
           Send Initialize_Shared_Data
           Move HOST_DATA_ALL To Mode
        End
        Send Data_Change Mode
    End_Procedure

    Procedure Initialize_Shared_Data
        Send Initialize_Button_Data
        Send Initialize_Caption_Data
        Send Initialize_Message_Data
        Send Initialize_Title_Data
        Send Initialize_Action_Data
        // 2002-10-14 ------------------------------------ Start Nils G. Svedmyr
        Send Initialize_License_Data
        // 2002-10-14 ------------------------------------ Stop Nils G. Svedmyr
    End_Procedure

    Procedure Initialize_Button_Data
        String sText
        Get HostData BUTTONSTART BUTTONLENGTH To sText
        Set Button_Text To sText
    End_Procedure

    Procedure Initialize_Caption_Data
        String sText
        Get HostData CAPTIONSTART CAPTIONLENGTH To sText
        Set Caption_Text To sText
    End_Procedure

    Procedure Initialize_Message_Data
        String sText
        Get HostData MESSAGESTART MESSAGELENGTH To sText
        Set Message_Text To sText
    End_Procedure

    Procedure Initialize_Action_Data
        String sText
        Get HostData ACTIONSTART ACTIONLENGTH To sText
        Set Action_Text To sText
    End_Procedure

    Procedure Initialize_Title_Data
        String sText
        Get HostData TITLESTART TITLELENGTH To sText
        Set Title_Text To sText
    End_Procedure

    // 2002-10-14 ------------------------------------ Start Nils G. Svedmyr
    Procedure Initialize_License_Data
        String sText
        Get HostData LICENSESTART LICENSELENGTH To sText
        Set License_Text To sText
    End_Procedure
    // 2002-10-14 ------------------------------------ Stop Nils G. Svedmyr

    Procedure Activate
       Send Initialize_Shared_Data
       Send Initialize_Text
       Forward Send Activate
    End_Procedure

    Procedure Initialize_Text
      Send Data_Change HOST_DATA_ALL
    End_Procedure

    Procedure Data_Change Integer DataChanged
    End_Procedure

End_Class

Class Center_mixin Is A Mixin

  Procedure Page_Object Integer St
      Handle hHnd
      Get Window_Handle To hHnd
      If (St And hHnd=0 ) ;
         Send Center_Object
      Forward Send Page_Object St
  End_Procedure

  Procedure Center_Object
      Integer iPrntSz iSz
      Delegate Get Client_Size To iPrntSz
      Get GuiSize To iSz
      Set GuiLocation To (Hi(GuiLocation(Current_Object))) ;
                       ( (Low(iPrntSz)-Low(iSz) Max 0 )/2 )
      Send Adjust_Logicals
  End_Procedure

End_Class

Class CenterTextBox Is A TextBox
   Import_Class_Protocol Center_Mixin
End_Class

Class SentinelButton Is A Button
   Import_Class_Protocol Center_Mixin
   Procedure OnCLick
      Send Close_Panel
   End_Procedure // OnCLick
End_Class