Use NewDfAbout.pkg

// This provides a quick and simple way to create an about package for a program.
// You need to create a message inside you client area called Activate_About.
// Within this message you should send the message DoAbout passing needed
// string information.
//
//       Procedure Activate_About
//           Send DoAbout sTitle sVersion sCopyright sAuthor sBitmap sWebSite
//       End_Procedure
//    where: sTitle =     Name of application. If none provided, uses caption
//                        bar title
//           sVersion   = Version Line. If none provided, will be blank
//           sCopyRight = Copyright Line. If none provided, will be blank
//           sAuthor    = Author name, blank if none provided
//           sBitMap    = Bitmap logo. If none provided, standard VDF bitmap
//                        is used.
//           sWebSite   = web site address
//           sAboutFilename = ASCII file with additonal information, locate in
//                            your app's help directory

//  Procedure Activate_About
//   Send DoAbout "The Farmer's Office 2000" "Version 1.9a (7/5/2000)" "Copyright 1999 Datatech" "All Rights Reserved" "newlogo.bmp" "about.txt"
//  End_Procedure

// *************************************************************************
//  Public message. It is expected that you will send this message (most
//  likely from Activate_About. This creates an about object, activates it
//  and destroys it when done. It is not exepected that you will augment this.
// *************************************************************************

//   Send DoAbout      sProduct        sVersion        sCopyright "Portions by Data Access WorldWide" "RDC48x48.bmp" "Rds.inf"
Procedure DoAbout String sTitle String sVersion String sCopyRight String sAuthor String sBitmap String sAboutFilename
  Integer hoObj hoMain
  String sHelpPath

  Object About Is An AboutDialog
    // If no title passed use the label of the main panel.
    If (Length(sTitle) = 0) Begin
      Get Main_Window To hoMain
      If hoMain Get Label Of hoMain To sTitle
    End

    Set Productname    To sTitle
    Set Version        To sVersion
    Set Copyright      To sCopyRight
    Set Author         To sAuthor
    Set Logo           To sBitMap
    Set Websiteaddress To ("Web site:  Http://www.rdctools.com")
    Set Emailaddress   To "E-mail: support@rdctools.com"

    If (Num_Arguments > 5) Begin
      Get psHelpPath Of (phoWorkspace(ghoApplication)) To sHelpPath
      Send ReadFile (sHelpPath + "\" + sAboutFilename)
    End // If (Num_Arguments > 5) Begin
    Move Self To hoObj
  End_Object

  Send Popup Of hoObj    // popup the about object
  Send Destroy_Object Of hoObj // when done, it will be destroyed
End_Procedure

Procedure Activate_About
  Handle ho
  String sPath sVersion sCopyright sProduct sProgram
  Integer iMajor iMinor iRelease iBuild
  Get phoVersionInfo   Of ghoApplication To ho
  Get piVersionMajor   Of ho To iMajor
  Get piVersionMinor   Of ho To iMinor
  Get piVersionRelease Of ho To iRelease
  Get piVersionBuild   Of ho To iBuild
  Move ("Version:" * String(iMajor) + "." + String(iMinor) + "." + String(iRelease) * "(Build " + String(iBuild) + ")") To sVersion
  Move ghoApplication To ho
  Get psProduct Of ho To sProduct
  Get psProgran Of ho To sProgram
  Get psCompany Of ho To sCopyright
  Move ("Copyright 2001-2003" * sCopyRight) To sCopyright
  Send DoAbout (sProduct * sProgram) sVersion sCopyright "Portions by Data Access WorldWide. 'CrossMerge Connection Builder' and 'CrossMerge Connection Engine' are trademarks of RDC Tools International." "RDC48x48.bmp/t/3d" "RDC.inf"
End_Procedure // Activate_About