//****************************************************************************
// $Module type: StatusBar Object
// $Module name: SDIStatusBar.pkg
// $Author     : Nils G. Svedmyr
// Created     : 2001-07-29 @ 16:08
//
// Description : To display a Statusbar at the bottom of any SDI panel.
//               You need to resize your SDI panel slightly to make room
//               for the Statusbar at the bottom.
//               This statusbar object only contains one object;
//               the status_help pane.
//               Put a 'Use SDIStatusBar' in the bottom code of the SDI panel.
//
// $Rev History:
//    2001-07-29  Module header created
//****************************************************************************
Use cStatusBar.pkg
//Set  Client_Id Self To Self // The cStatusBar class needs a Client handle.

Procedure Adjust_SDI_Margins Integer iSizeY Integer iSizeX Integer iBorderFlag
  Integer cMargin
  If (iBorderFlag = amTOP) Begin
    Get Mdi_Top_Margin To cMargin
    Set Mdi_Top_Margin To (cMargin + iSizeY)
  End
  Else If (iBorderFlag = amBOTTOM) Begin
    Get Mdi_Bottom_Margin To cMargin
    Set Mdi_Bottom_Margin To (cMargin + iSizeY)
  End
  Else If (iBorderFlag = amLEFT) Begin
    Get Mdi_Left_Margin To cMargin
    Set Mdi_Left_Margin To (cMargin + iSizeX)
  End
  Else If (iBorderFlag = amRIGHT) Begin
    Get Mdi_Right_Margin To cMargin
    Set Mdi_Right_Margin To (cMargin + iSizeX)
  End
End_Procedure

Procedure Add_Border_Object Integer hoBorder Integer iBorderFlag
  Integer iSizeY iSizeX
  Move (Hi(GuiSize(hoBorder)))  To iSizeY
  Move (Low(GuiSize(hoBorder))) To iSizeX
  Send Adjust_SDI_Margins iSizeY iSizeX iBorderFlag
End_Procedure

Procedure Remove_Border_Object Integer hoBorder Integer iBorderFlag
  Integer iSizeY iSizeX
  Move (-(Hi(GuiSize(hoBorder))))  To iSizeY
  Move (-(Low(GuiSize(hoBorder)))) To iSizeX
  Send Adjust_SDI_Margins iSizeY iSizeX iBorderFlag
End_Procedure

Object oStatusBar Is A cStatusBar
  Set pbSizeGrip To True
  Set pbSimple   To True
  Set peAlign    To anLeftRight
  Procedure Show_View_Name String sName
  End_Procedure
  Procedure Set Status_Help String sHelp
    Set psSimpleValue To (Trim(sHelp))
  End_Procedure // Set Status_Help
  Function Item_Count Returns Integer
  End_Function // Status_Help

  Delegate Set piVerStatBar To (Hi(GuiSize(Self))) // oMain property.

End_Object // oStatusBar