//****************************************************************************
// $Module type: CLASS
// $Module name: cdbCheckboxNtAuth.pkg
// $Author     : Nils G. Svedmyr
// Created     : 2002-09-25 @ 08:26
//
// Description :
//
// $Rev History
//    2002-09-25  Module header created
//****************************************************************************
Use cRdsDbCheckBox.pkg

Class cDbCheckboxNtAuth Is A cRdsDbCheckBox
  Procedure Construct_Object
    Forward Send Construct_Object
    Property Handle phoUserObject     0
    Property Handle phoPasswordObject 0
    Property Handle phoDD             (Main_DD(Self))
    Property Integer piDbType     0
    // Visual DataFlex 12.0 Migration Utility, added March 28, 2007: 15:13:25
    #IF (!@ >= 120)
    { InitialValue=True }
    #ENDIF
    Property Boolean pbFrom       True
  End_Procedure // Construct_Object

  Procedure End_Construct_Object
    Forward Send End_Construct_Object
  End_Procedure // End_Construct_Object

  Procedure DoEnableDisable Integer iValue
    Handle hoDD
    Set piDbType To iValue
    Get phoDD    To hoDD
    //If (iValue = 4) Set Visible_State To False
    //Else            Set Visible_State To True
    Set Enabled_State To (iValue = 3 Or iValue = 5)
    If Not (Enabled_State(Self)) ;
      Set Select_State item 0 To False
    If (Not(Current_Record(hoDD)) And iValue = 3) ;
      Set Select_State item 0 To True
  End_Procedure // DoEnableDisable

  Procedure OnChange
    Handle hoDD ho
    Boolean bSelect
    Integer iFile iField iFromState iToState iShould_Save iChanged_State
    If Not (Active_State(Self))  Procedure_Return
    If Not (Enabled_State(Self)) Procedure_Return

    Get Main_DD       To hoDD
    Get Select_State  To bSelect
    If (Not(phoUserObject(Self)) Or Not(phoPasswordObject(Self))) Begin  // Only do this once.
      If (pbFrom(Self)) Begin
        Get DDObjectId hoDD SncTable.File_Number "FromUser" To ho // Global function in Sysfuncs.pkg
        Set phoUserObject                                   To ho
        Get DDObjectId hoDD SncTable.File_Number "FromPv"   To ho
        Set phoPasswordObject                               To ho
      End // If (pbFrom(Self)) Begin
      Else Begin
        Get DDObjectId hoDD SncTable.File_Number "ToUser"   To ho
        Set phoUserObject                                   To ho
        Get DDObjectId hoDD SncTable.File_Number "ToPv"     To ho
        Set phoPasswordObject                               To ho
      End // Else Begin
    End // If (Not(phoUserObject(Self)) Or Not(phoPasswordObject(Self))) Begin  // Only do this once.
    Set Enabled_State Of (phoUserObject(Self))         To (Not(bSelect))
    Set Enabled_State Of (phoPasswordObject(Self))     To (Not(bSelect))
    If Not bSelect Procedure_Return
    Get Should_Save   Of hoDD                          To iShould_Save
    Get Changed_State Of hoDD                          To iChanged_State
    Get Data_File     Of (phoUserObject(Self))         To iFile
    Get Data_Field    Of (phoUserObject(Self))         To iField
    Get File_Field_Changed_State Of hoDD iFile iField  To iFromState
    Set File_Field_Changed_Value Of hoDD iFile iField  To ""
    Set File_Field_Changed_State Of hoDD iFile iField  To iFromState
    Get Data_File  Of (phoPasswordObject(Self))        To iFile
    Get Data_Field Of (phoPasswordObject(Self))        To iField
    Get File_Field_Changed_State Of hoDD iFile iField  To iToState
    Set File_Field_Changed_Value Of hoDD iFile iField  To ""
    Set File_Field_Changed_State Of hoDD iFile iField  To iToState
    Set Changed_State Of hoDD                          To iChanged_State
  End_Procedure // OnChange

End_Class // cdbCheckboxNtAuth