//****************************************************************************
// $Module type: CLASS
// $Module name: DoInitValue
// $Author     : Nils G. Svedmyr
// Created     : 2002-07-21 @ 09:30
//
// Description :
//
// $Rev History
//    2002-07-21  Module header created
//****************************************************************************

Class cDbFormPassword Is A cRDSDbForm
  Procedure Construct_Object
    Forward Send Construct_Object
    Property Integer piDbType 0
    Property Handle  phoDD    (Main_DD(Self))
    Property String Private.StatusHelp ""     // Do _not_ use Private.Status_Help. It is defined in base class.
    Set Password_State Item 0 To True
    Set Entry_msg To DoCheckEntering
  End_Procedure // Construct_Object

  Procedure End_Construct_Object
    Forward Send End_Construct_Object
  End_Procedure // End_Construct_Object

  Procedure DoCheckEntering
//    If Not (Enabled_State(Self)) Send Next
  End_Procedure // DoCheckEntering

  Procedure DoEnableDisable Integer iValue
    Set piDbType To iValue
    Set Enabled_State To (iValue > 1)
    Send DoClearDisabled
  End_Procedure // DoEnableDisable

  Procedure DoClearDisabled
    Handle hoDD
    Integer iFile iField
    Boolean bChanged
    String sHelp

    Get Private.StatusHelp   To sHelp
    If (sHelp = "") Begin
      Get Status_Help Item 0 To sHelp
      Set Private.StatusHelp To sHelp
    End // If (sHelp = "") Begin

    Get phoDD      To hoDD
    Get Data_File  To iFile
    Get Data_Field To iField
    If Not (Enabled_State(Self)) Begin
      Get File_Field_Changed_State   Of hoDD iFile iField To bChanged
      If bChanged ;
        Set File_Field_Changed_Value Of hoDD iFile iField To ""
    End // If Not (Enabled_State(Self)) Begin
    If (piDbType(Self) < 6) Begin
      Get Private.StatusHelp To sHelp
      Set Status_Help        To sHelp
    End // If (piDbType(Self) < 6) Begin
    Else Begin                   // Pervasive
      Set Status_Help To ;
        ("Pervasive.SQL (Btrieve) have a concept called the ownername of a file." * ;
          "The value of an ownername is not the name as the person who created the file" * ;
          "or the person who owns it. You should think of ownernames like passwords."    * ;
          "People who know the password have unlimited access, while people who don't, have not." * ;
          "NOTE: Ownernames are case sensitive!")
    End // Else Begin

  End_Procedure // DoClearDisabled

End_Class // cDbFormPassword