//****************************************************************************
// $Module type: Class
// $Module name: cDbFormUser
// $Author     : Nils G. Svedmyr
// Created     : 2002-07-21 @ 09:07
//
// Description :
//
// $Rev History:
//    2002-07-21  Module header created
//****************************************************************************
Use cRDSDbForm.pkg
Use NewDfAbout.pkg

Class cDbFormUser is a cRDSDbForm
  Procedure Construct_Object
    Forward Send Construct_Object
    Property Integer piDbType 0
    // Visual DataFlex 12.0 Migration Utility, added March 28, 2007: 15:13:24
    #IF (!@ >= 120)
    { InitialValue=True }
    #ENDIF
    Property Boolean pbFrom   False
    Property Handle  phoDD    (Main_DD(Self))
    Set Entry_msg To DoCheckEntering
  End_Procedure // Construct_Object

  Procedure End_Construct_Object
    Forward Send End_Construct_Object
  End_Procedure // End_Construct_Object

  Procedure DoCheckEntering
//    If Not (Enabled_State(Self)) Send Next
  End_Procedure // DoCheckEntering

  Procedure DoEnableDisable Integer iValue
    Set piDbType To iValue
    Set Enabled_State To (iValue > 1 And iValue < 6) // 6 = Pervasive
    Send DoInitValue
  End_Procedure // DoEnableDisable

  Procedure DoInitValue
    Handle hoDD
    Integer iFile iField iType
    String sValue
    Boolean bNTAuth

    Get phoDD      To hoDD
    Get piDbType   To iType
    Get Data_File  To iFile
    Get Data_Field To iField

    If (pbFrom(Self)) Get Field_Current_Value of hoDD Field SncTable.FromNTAuth To bNTAuth
    Else              Get Field_Current_Value of hoDD Field SncTable.ToNTAuth   To bNTAuth

    Case Begin
      Case (iType = 1)                              // DataFlex
        Move "" to sValue
        Case Break
      Case (iType = 2)                              // IBM DB2 UDB
        Get Network_User_Name to sValue
        Case Break
      Case (iType = 3)                              // MS SQL
        If Not bNTAuth Get Network_User_Name to sValue
        Case Break
      Case (iType = 4)                              // ODBC
        Move "" to sValue
        Case Break
      Case (iType = 5)                              // Oracle
        Get Network_User_Name to sValue
        Case Break
      Case (iType = 6)                              // Pervasive
        //Get Network_User_Name to sValue
        Case Break
      Case Else
        Move "" To sValue
    Case End

    If Not (Current_Record(hoDD)) Set File_Field_Changed_Value of hoDD iFile iField to sValue
  End_Procedure // DoInitValue

End_Class // cDbFormUser