//***************************************************************************
//*
//* Class:        cRDSSpinForm
//* Package Name: cRDSSpinForm.pkg
//*
//***************************************************************************
Use DFAllEnt.pkg
Use cTooltip.pkg

Register_Object oToolbar
Register_Procedure Set phoCopy  Handle ho
Register_Procedure Set phoPaste Handle ho
Register_Procedure Set phoCut   Handle ho

Class cRDSSpinForm is a SpinForm

  Procedure Construct_object
    Forward Send Construct_Object
    Property Handle Private.phoToolTip 0
    Object oTooltip Is A cTooltip
      Set Private.phoToolTip To (Self)
    End_Object // oTooltip
    Set Exit_msg         To DoEnableToolbarButtons
    Set Entry_msg        To DoDisableToolbarButtons
  End_Procedure

  Procedure End_Construct_Object
    Handle ho
    String sHelp
    Boolean bVisible bPopup
    Forward Send End_Construct_Object
    Get Private.phoToolTip To ho
    Get Visible_State      To bVisible
    If (ho > 0 And bVisible = True) Begin
      Delegate Get Popup_State To bPopup
      If (bPopup = False) Send Activate Of ho
    End // If (ho > 0 And bVisible = True) Begin
  End_Procedure // End_Construct_Object

  Procedure Set pbHidden Boolean bMode
    Handle ho
    Get Label_Object               To ho
    Set Visible_State              To (Not(bMode))
    If ho Set Visible_State  Of ho To (Not(bMode))
    Set Enabled_State              To (Not(bMode))
    If ho Send Enable_Window Of ho    (Not(bMode))
    Set Focus_Mode                 To (If(bMode = True, NonFocusable, Focusable))
  End_Procedure // Set pbHidden

  Function pbHidden Returns Boolean
    Function_Return (Visible_State(Self))
  End_Function // pbHidden

  Procedure DoEnableToolbarButtons
    Handle ho
    If (Entry_State(Self, 0)) Procedure_Return
    Move (oToolBar(Self)) To ho
    If ho Begin
      Get phoCut          To ho
      If ho Set pbEnabled Of ho To True
      Get phoCopy         To ho
      If ho Set pbEnabled Of ho To True
      Get phoPaste        To ho
      If ho Set pbEnabled Of ho To True
    End // If ho Begin
  End_Procedure // DoEnableToolbarButtons

  Procedure DoDisableToolbarButtons
    Handle ho
    Boolean bState
    If (Entry_State(Self, 0)) Procedure_Return
    Move (oToolBar(Self)) To ho
    If ho Begin
      Get phoCut          To ho
      If ho Set pbEnabled Of ho To False
      Get phoCopy         To ho
      If ho Set pbEnabled Of ho To False
      Get phoPaste        To ho
      If ho Set pbEnabled Of ho To False
    End // If ho Begin
  End_Procedure // DoDisableToolbarButtons

  Procedure Set pbToolTips Boolean bState
    Handle ho
    Get Private.phoToolTip To ho
    If ho Begin
      If (bState = False) Send DeActivate Of ho
      Else                Send Activate   Of ho
    End // If ho Begin
  End_Procedure // Set pbToolTips

  Procedure Page Integer iFlag
    Handle ho hWnd
    String sHelp
    Boolean bVisible bPopup
    Forward Send Page iFlag
    Get Private.phoToolTip To ho
    Get Visible_State      To bVisible
    If (ho And bVisible) Begin
      Get Status_Help Item 0 To sHelp
      Set psTooltip    Of ho To (ToAnsi(sHelp))
      If (Enabled_State(Self)) Get Form_Window_Handle To hWnd
      Else                     Get Window_Handle      To hWnd
      If (iFlag And ho > 0 And hWnd > 0) Send AddTool Of ho hWnd
    End // If (ho And bVisible) Begin
  End_Procedure // Page

  Procedure Destroy
    Send DestroyToolTip
    Forward Send Destroy
  End_Procedure // Destroy

  Procedure DestroyToolTip
    Handle ho
    Get Private.phoToolTip To ho
    If ho Begin
      Send Destroy    Of ho
      Set Private.phoToolTip To 0
    End // If ho Begin
  End_Procedure // DestroyToolTip

End_Class // cRDSSpinForm