Use cAutoWebReport.pkg
Use cWebBusinessProcess.pkg
Use DataDict.pkg
Use cWebReport.pkg
Use Vendor.DD

Object oVendor is a cWebBusinessProcess
    Set pbClearAfterSave to False
    Set psDescription to "Vendor: Entry, Reporting and Maintenance"

    Object Vendor_DD is a Vendor_DataDictionary
        Send DefineAllExtendedFields
    End_Object    // Vendor_DD

    Set Main_DD to Vendor_DD

    Object oReport is a cWebReport

        Procedure OnPageTop
            Send WriteHtmlTableBegin 'border="0" width="99%" Class="ReportTable"'

            Send WriteHtmlRowBegin
                Send WriteHtmlCellHeader 'Vndr ID' 'Class="Header" Align="right"'
                Send WriteHtmlCellHeader 'Name' 'Class="Header" Align="left"'
                Send WriteHtmlCellHeader 'Address' 'Class="Header" Align="left"'
                Send WriteHtmlCellHeader 'City' 'Class="Header" Align="left"'
                Send WriteHtmlCellHeader 'St.' 'Class="Header" Align="left"'
                Send WriteHtmlCellHeader 'Zip' 'Class="Header" Align="left"'
                Send WriteHtmlCellHeader 'Phone' 'Class="Header" Align="left"'
                Send WriteHtmlCellHeader 'Fax' 'Class="Header" Align="left"'
            Send WriteHtmlRowEnd
        End_Procedure // OnPageTop

        Procedure OnBody
            String sText
            Number nId
            String sName sAddress sCity sState sZip sPhone sFax

            Get ddValueEncode "Vendor.ID" To nID
            Get ddValueEncode "Vendor.Name" To sName
            Get ddValueEncode "Vendor.Address" To sAddress
            Get ddValueEncode "Vendor.City" To sCity
            Get ddValueEncode "Vendor.State" To sState
            Get ddValueEncode "Vendor.Zip" To sZip
            Get ddValueEncode "Vendor.Phone_Number" To sPhone
            Get ddValueEncode "Vendor.Fax_Number" To sFax
            Send WriteHtmlRowBegin
                Get AddRowIdLink (FormatNumber(nId,0)) To sText
                Send WriteHtmlCell sText 'Class="Data" Align="right"'
                Send WriteHtmlCell sName 'Class="Data" Align="left"'
                Send WriteHtmlCell sAddress 'Class="Data" Align="left"'
                Send WriteHtmlCell sCity 'Class="Data" Align="left"'
                Send WriteHtmlCell sState 'Class="Data" Align="left"'
                Send WriteHtmlCell sZip 'Class="Data" Align="left"'
                Send WriteHtmlCell sPhone 'Class="Data" Align="left"'
                Send WriteHtmlCell sFax 'Class="Data" Align="left"'
            Send WriteHtmlRowEnd
        End_Procedure // OnBody

        Procedure OnPageBottom
            Send WriteHtmlTableEnd
        End_Procedure // OnPageBottom

        Function RunVendorList Integer iIndex RowId riStart Integer iMax Returns RowId
            RowId riEnd
            integer  iStat

            Set piOrdering           To iIndex
            Set piMaxCount           To iMax
            Set piMaxCountBreakLevel To 0
            Set priStartRowId        To riStart
            Get DoRunReport          To iStat
            Get priLastRowId         To riEnd
            Function_Return riEnd
        End_Function // RunVendorList

    End_Object    // oReport

    { Published = True  }
    { Description = ""  }
    Procedure SetHRefName String sName
        Set psHRefname Of oReport To sName
    End_Procedure // SetHRefName

    { Published = True  }
    { Description = ""  }
    Function RunVendorList Integer iIndex string sStart Integer iMax Returns string
        RowId riStart riEnd
        Move (DeserializeRowID(sStart)) to riStart
        Get RunVendorList Of oReport iIndex riStart iMax To riEnd
        Function_Return (SerializeRowId(riEnd))
    End_Function // RunVendorList

    //  Register WBO interfaces
    Send RegisterStandardInterface
    //Send RegisterDebugInterface
    //Send RegisterFullErrorInterface

    // These are used by Vendor0.asp as an example of an auto entry, auto-report
    Send RegisterAutoEntryInterface
    Object oAutoWebReport Is A cAutoWebReport
    End_Object

End_Object    // oVendor