//------------------------------------------------------------>
// GlbIndexData.dg
//
// Entry of index # and data for jumping in and out of indexes
//
// Yeah, it uses direct references to the parent view, but
// it's been that way for years and it's too much trouble to
// change.
//------------------------------------------------------------>
// Register all objects
Register_Object Cancel_Button
Register_Object Index#
Register_Object JumpIn_Data
Register_Object JumpOut_Data
Register_Object Ok_Button
Register_Object oIndexEntry
Register_Object oReturnText

Use Windows.pkg


CD_Popup_Object oIndexEntry is a ModalPanel

    On_Key KCancel Send Close_Panel

    Set Label to "Index Selection"
    Set Location to 6 6
    // Visual DataFlex 14.0 Client Size Adjuster, modified April 22, 2008: 20:37:23
//    Set Size to 130 300
    Set Size to 115 296

    Object Index# is a Form
        Set Label to "Index #:"
        Set Size to 13 28
        Set Location to 10 67
        Set Label_Col_Offset to 33

        Set Prompt_Button_Mode to pb_PromptOn
        
        Procedure Prompt
            Integer iIndex#
            Set piIndex# Of (oReplace_View(Self)) To ""
            Send Popup To (oIndexLookUp(Self))
            Get piIndex# Of (oReplace_View(Self)) To iIndex#
            Set Value Item 0 To iIndex#
        End_Procedure
        
        Procedure Exiting integer lToObj
            Integer iIndex#
            Get Value Item 0 To iIndex#
            Set piIndex# Of (oReplace_View(Self)) To iIndex#
            Forward Send Exiting lToObj
        End_Procedure

    End_Object    // Index#

    Object oReturnText is a Textbox
        Set Label to "Do not enclose data in quotes."
        Set Location to 30 100
        Set Size to 10 155
        Set TypeFace to "MS Sans Serif"
    End_Object    // oReturnText

    Object JumpIn_Data is a Form
        Set Label to "'Jump In' Data:"
        Set Size to 13 207
        Set Location to 44 67

        Procedure Exiting Integer iToObj
            String sIndex_Data sChar
            Integer iFail
            Forward Get MSG_Exiting iToObj to iFail
            If (not(iFail)) Begin 
                If (iToObj = Cancel_Button(Self)) Procedure_Return iFail
                Get Value to sIndex_Data
                Move (Trim(sIndex_Data)) to sIndex_Data
                Move (Left(sIndex_Data, 1)) to sChar
                If (sChar = '"' or sChar = "'") Begin 
                    Send Stop_Box "Do not use quotes in 'Jump-in' data." "ERROR!"
                    Procedure_Return 1
                End
                Set psJumpin_Data of (oReplace_View(Self)) to sIndex_Data
            End
            Procedure_Return iFail
        End_Procedure

    End_Object    // JumpIn_Data

    Object JumpOut_Data is a Form
        Set Label to "'Jump Out' Data:"
        Set Size to 13 207
        Set Location to 72 67

        Procedure Exiting integer iToObj
            String sIndex_Data sChar
            Integer iFail
            Forward Get MSG_Exiting iToObj to iFail
            If (not(iFail)) Begin 
                If (iToObj = Cancel_Button(Self)) Procedure_Return iFail
                Get Value to sIndex_Data
                Move (Trim(sIndex_Data)) to sIndex_Data
                Move (Left(sIndex_Data, 1)) to sChar
                If (sChar = '"' or sChar = "'") Begin 
                    Send Stop_Box "Do not use quotes in 'Jump-out' data." "ERROR!"
                    Procedure_Return 1
                End
                Set psJumpOut_Data of (oReplace_View(Self)) to sIndex_Data
            End
            Procedure_Return iFail
        End_Procedure

    End_Object    // JumpOut_Data

    Object Ok_Button is a Button
        Set Label to "OK"
        Set Location to 94 179

        Procedure OnClick
            Send Close_Panel
        End_Procedure

    End_Object    // Ok_Button

    Object Cancel_Button is a Button
        Set Label to "Cancel"
        Set Location to 94 237

        Procedure OnClick
            Set piIndex# Of (oReplace_View(Self)) To ""
            Set psJumpin_Data Of (oReplace_View(Self)) To ""
            Set psJumpOut_Data of (oReplace_View(Self)) to ""
            Send Close_Panel
        End_Procedure

    End_Object    // Cancel_Button

CD_End_Object    // oIndexEntry