//TH-Header
//*****************************************************************************************
// Copyright (c)  2012 Antwise Solutions
// All rights reserved.
//
// $FileName    : cDragDropdbTabPage
// $ProjectName : Order Entry Example
// $Authors     : Wil van Antwerpen
// $Created     : 11.29.2012  10:37
// $Type        : Commercial
//
// Contents:
//
//*****************************************************************************************
//TH-RevisionStart
//TH-RevisionEnd
Use Dftabdlg.pkg
Use cDragDropHandler.pkg

Class cDragDropdbTabPage is a dbTabPage
  
  Procedure Construct_Object
    
    Forward send Construct_Object
  End_Procedure // Construct_Object
  
  Procedure doRegisterDragDrop
    Handle  hWnd
    Handle  hDnDWnd
    Integer iVoid
    
    Get Window_Handle to hWnd
    If (hWnd) begin
      If (ghoDragDropHandler) Begin
        Set phoDropContainer of ghoDragDropHandler to Self
        Get Window_Handle of ghoDragDropHandler to hDnDWnd
        If (hDnDWnd) Move (RegisterDragDropDLL(hWnd,hDnDWnd,WM_OLEDROP)) to iVoid
        Else Error 300 "The object for handling Drag and drop operations does not have a windows handle."
      End
      Else Error 300 "The global Drag and Drop handler has not been set."
    End
    Else Begin
      Error 300 "The object for receiving Drag and drop operations does not have a windows handle."
    End  
  End_Procedure // doRegisterDragDrop
  
  Procedure Page_Delete
    
    Send doRevokeDragDrop
    Forward Send Page_Delete
  End_Procedure
  
  Procedure doRevokeDragDrop 
    Handle  hWnd
    Integer iVoid
    
    Get Window_Handle to hWnd
    If (hWnd) Begin
      Move (revokeDragDropDLL(hWnd)) to iVoid
    End
  End_Procedure // doRevokeDragDrop  
  
  Procedure Page_Object Boolean bState
    
    Forward Send Page_Object bState
    If (bState) Begin 
      Send doRegisterDragDrop
    End  
  End_Procedure // Page_Object
  
  // 
  // Event that is being send when one or more items are being dropped on 
  // our panel via the OLE drag and drop method. 
  //
  Procedure onDropTarget
  End_Procedure // onDropTarget  
  
End_Class // cDragDropdbTabPage