Use cWebView.pkg
Use cWebPanel.pkg
Use cWebForm.pkg
Use cCustomerDataDictionary.DD
Use cWebList.pkg
Use cWebColumn.pkg
Use cWebColumnLink.pkg
Use cWebButton.pkg
Use cWebLabel.pkg
Use cWebColumnButton.pkg

Use FileUploadTest.wo

Object oDAWWebListCustomerList is a cWebView
    Set psCaption to "DAW cWebList Customer table (for testing differences and debugging only)"
    Set peViewType to vtSelect

    // Your DDO structure will go here
    Object oCustomer_DD Is a cCustomerDataDictionary
    End_Object
    
    Set Main_DD to oCustomer_DD
    Set Server to oCustomer_DD
    
    Procedure OnLoad
        Send Find of oCustomer_DD FIRST_RECORD 1
    End_Procedure

    Object oWebMainPanel is a cWebPanel
        Set piColumnCount to 12
        
        // place controls here.
        // Your view will grow as controls are added
        
        Object oForm is a cWebForm
            Set piColumnSpan to 2
            Set psLabel to "Label 1:"
        End_Object

        Object oWebButton1 is a cWebButton
            Set piColumnSpan to 1
            Set piColumnIndex to 3
            Set psCaption to "test"
        
            Procedure OnClick
              String sValue
              // test if this is read from db before show (probably not)
              WebGet psValue of oCustomer_Zip to sValue
              Send ShowInfoBox ("customer zip ="+sValue)
            End_Procedure
        End_Object

        Object oNewRowLabel is a cWebLabel
          Set psCaption to "New Row Label"
          Set piColumnSpan to 3
          Set piColumnIndex to 4
        End_Object

        Object oUploadButton is a cWebButton
            Set piColumnSpan to 2
            Set psCaption to "File Upload"
            Set piColumnIndex to 7
        
            Procedure OnClick
              String sRowID
              Move "" To sRowID
              Send PopupTheDialog of oFileUploadTest Self sRowID
            End_Procedure
        End_Object

        Object oCustomerWebGrid is a cWebList
            Set piColumnIndex to 0
            Set piColumnSpan  to 12
            Set piHeight        To 400
            Set Server to oCustomer_DD
            
            Procedure OnChangeCurrentRow String sFromRowID String sToRowID
              String sName
              WebGet psValue of oCustomer_Name To sName
              WebSet psCaption of oNewRowLabel to ("Row: "+sName)
            End_Procedure  
        
            Object oCustomer_Customer_Number is a cWebColumn
                Entry_Item Customer.Customer_Number
                Set psCaption To "Number"
                Set piWidth to 50
            End_Object

            Object oCustomer_Name is a cWebColumnLink
                Entry_Item Customer.Name
                Set psCaption to "Customer Name"
                Set piWidth to 196
                
                Procedure OnClick String sRowID String sCellValue
                    Send ShowInfoBox sRowId
                End_Procedure                
            End_Object

            Object oCustomer_State is a cWebColumn
                Entry_Item Customer.State
                Set psCaption to "St."
                Set piWidth to 77
            End_Object

            Object oCustomer_Zip is a cWebColumn
                Entry_Item Customer.Zip
                Set psCaption to "Zip"
                Set piWidth to 71
            End_Object

            Object oCustomer_Status is a cWebColumnCheckbox
                Entry_Item Customer.Status
                Set psCaption to "Active?"
                Set piWidth to 50
            End_Object
            
            Object oFontIcon is a cWebColumnButton
              Set piWidth to 19
              Set psCaption to "button"
              //Set psBtnCssClass to "WebButtonIcon WebIcon_Info"
              Set pbDynamic to True
            
              Procedure OnClick String sButton String sRowId
                  Forward Send OnClick sButton sRowId
                  Send ShowInfoBox ("button clicked "+sButton )
              End_Procedure
          
              // Called for each row to define the buttons that need to be displayed.
              Procedure OnDefineButtons
                  // Use AddButton to define a button (sID, sCaption, sCSSClass)
                  Send AddButton "E" "Edit" ""
          
                  // The Global buffer contains the right record for data aware lists
                  If (Customer.Status = "Y") Begin
                      Send AddButton "D" "Deactivate" ""
                  End
              End_Procedure
              
            End_Object

        End_Object
    End_Object
End_Object