//TH-Header
//*****************************************************************************************
// Copyright (c)  2022 Antwise Solutions
// All rights reserved.
//
// $FileName    : SyncFusion\AppSrc\csfWebChartArea.pkg
// $ProjectName : SyncFusion Library
// $Authors     : Wil van Antwerpen
// $Created     : 2022-08-28  15:50
//
// Contents:
//  This is used for configuring the Chart area that you can use in a csfWebChart
//
// Documentation for the API is here:
// https://ej2.syncfusion.com/documentation/api/chart/chartArea/
//
//
//*****************************************************************************************
//TH-RevisionStart
// ********************
// MODIFICATION SUMMARY
// ********************
// ####### DD/MM/YYYY  WHO COMMENT
//TH-RevisionEnd
Use csfWebChartChild.pkg

// https://ej2.syncfusion.com/documentation/api/chart/chartArea/
Struct tsfWebChartArea
  String  sBackground
  String  sBackgroundImage
  tsfWebChartBorderModel border
  Number  nOpacity
  Integer iWidth   // pixels only
End_Struct


{ OverrideProperty=pbFillHeight Visibility=Private }
Class csfWebChartArea Is a csfWebChartChild

  Procedure Construct_Object
    Forward Send Construct_Object
    
    { WebProperty=Client }
    Property String  psBackground            ""
    { WebProperty=Client }
    Property String  psBackgroundImage       ""
    { WebProperty=Client }
    Property String  psBorderColor           ""
    // Set the width in pixels. If the width is -1 (C_WebDefault) then it will
    // use the default.
    { WebProperty=Client }
    Property Integer piBorderWidth           C_WebDefault
    // Set the opacity in a value between 0.0 and 1.0. If the width is -1 (C_WebDefault) then it will
    // use the default of 1.0
    { WebProperty=Client }
    Property Number  pnOpacity               C_WebDefault
    // Set the width in pixels. If the width is -1 (C_WebDefault) then it will
    // use the default.
    { WebProperty=Client }
    Property Integer piWidth                 C_WebDefault
    
    
    // We set this to false, so we can detect if a DAW webcolumn was dropped
    // as it will have this set to true.
    Property Boolean pbIsWebColumn           False
    //
    Set psJSClass To "sf.WebChartArea"
  End_Procedure
  
      
  Function LoadWebChartAreaProperties Returns tsfWebChartArea
    tsfWebChartArea Area
    Get psBackground      To Area.sBackground
    Get psBackgroundImage To Area.sBackgroundImage
    Get psBorderColor     To Area.border.sColor
    Get piBorderWidth     To Area.border.iWidth
    Get pnOpacity         To Area.nOpacity
    Get piWidth           To Area.iWidth
    Function_Return Area
  End_Function
  
  Procedure ConnectArea
    String[] aParams
    Send ClientAction "connectArea" aParams
  End_Procedure

  Procedure End_Construct_Object
    Forward Send End_Construct_Object
    Delegate Send RegisterArea Self
  End_Procedure
End_Class