//TH-Header
//*****************************************************************************************
// Copyright (c)  2022 Antwise Solutions
// All rights reserved.
//
// $FileName    : SyncFusion\AppSrc\csfWebChartAxis.pkg
// $ProjectName : SyncFusion Library
// $Authors     : Wil van Antwerpen
// $Created     : 2022-08-26  15:50
//
// Contents:
//  This is used for configuring the various axes that you can use in a csfWebChart
//  Most charts have an X-Axis and a Y-Axis.
//
// Documentation for the API is here:
// https://ej2.syncfusion.com/documentation/api/chart/axisModel/
//
//
//*****************************************************************************************
//TH-RevisionStart
// ********************
// MODIFICATION SUMMARY
// ********************
// ####### DD/MM/YYYY  WHO COMMENT
//TH-RevisionEnd
Use csfWebChartChild.pkg

Define chartAxisX For 0
Define chartAxisY For 1

// https://ej2.syncfusion.com/documentation/api/chart/axisModel/
Struct tsfWebChartAxis
  Integer eAxisType        // 0=X-Axis, 1=Y-Axis
//  Integer iColumnIndex
  String  sDescription
//  Integer iDesiredIntervals
  String  sEdgeLabelPlacement
//  Boolean bEnableAutoIntervalOnZooming
//  Boolean bEnableScrollBarOnZooming
//  Boolean bEnableTrim
  Integer iInterval
  String  sIntervalType
//  Boolean bIsIndexed
//  Boolean bIsInversed
  String  sLabelFormat
//  String  sLabelIntersecAction
//  Integer iLabelPadding
//  String  sLabelPlacement
//  String  sLabelPosition
//  Integer iLabelRotation
  Integer iLogBase
  Integer iMinimum
  Integer iMinorTicksPerInterval
  Integer iMaximum
  String  sName
//  Boolean bOpposedPosition
//  Integer iRowIndex
//  Boolean bStartFromZero
//  Integer iTabIndex
//  String  sTickPosition
  String  sTitle
//  Integer iTitlePadding
  String  sValueType
  Boolean bVisible
End_Struct


{ OverrideProperty=pbFillHeight Visibility=Private }
Class csfWebChartAxis Is a csfWebChartChild

  Procedure Construct_Object
    Forward Send Construct_Object
    
    { WebProperty=Client }
    Property String  psDescription           ""
    
    { WebProperty=Client }
    Property Integer piInterval              C_WebDefault
    
    { EnumList="Auto, Years, Months, Days, Hours, Minutes, Seconds" }
    { WebProperty=Client }
    Property String  psIntervalType          ""
    
    { EnumList="None, Hide, Shift" }
    { WebProperty=Client }
    Property String  psEdgeLabelPlacement    ""
    { WebProperty=Client }
    Property String  psLabelFormat           ""

    // The base value for logarithmic axis. It requires valueType to be Logarithmic
    { WebProperty=Client }
    Property Integer piLogBase               C_WebDefault
    
    { WebProperty=Client }
    Property Integer piMinimum               C_WebDefault
    
    { WebProperty=Client }
    Property Integer piMinorTicksPerInterval C_WebDefault
    
    { WebProperty=Client }
    Property Integer piMaximum               C_WebDefault
    
    { WebProperty=Client }
    Property String  psName                  ""
    
    { WebProperty=Client }
    Property String  psTitle                 ""
    
    { EnumList="chartAxisX, chartAxisY" }
    { InitialValue=chartAxisX }
    { WebProperty=Client }
    Property Integer peAxisType              chartAxisX
    
    { EnumList="Double, DateTime, Category, Logarithmic, DateTimeCategory" }
    { WebProperty=Client }
    Property String  psValueType             ""
    
    // We set this to false, so we can detect if a DAW webcolumn was dropped
    // as it will have this set to true.
    Property Boolean pbIsWebColumn           False
    //
    Set psJSClass To "sf.WebChartAxis"
  End_Procedure
  
      
  Function LoadWebChartAxisProperties Returns tsfWebChartAxis
    Integer eAxisType
    String  sName
    tsfWebChartAxis Axis
    Get peAxisType        To eAxisType
    Move eAxisType        To Axis.eAxisType
    Get psDescription     To Axis.sDescription
    Get psEdgeLabelPlacement To Axis.sEdgeLabelPlacement
    Get piInterval        To Axis.iInterval
    Get psIntervalType    To Axis.sIntervalType
    Get psLabelFormat     To Axis.sLabelFormat
    Get piLogBase         To Axis.iLogBase
    Get piMinimum         To Axis.iMinimum
    Get piMinorTicksPerInterval To Axis.iMinorTicksPerInterval
    Get piMaximum         To Axis.iMaximum
    Get psName            To sName
    If (sName="") Begin
      If (eAxisType=chartAxisX) Begin
        Move "link-X" To sName
      End
      Else Begin
        Move "link-Y" To sName
      End
      Set psName To sName
    End
    Move sName           To Axis.sName
    Get psTitle          To Axis.sTitle
    Get psValueType      To Axis.sValueType
    Get pbVisible        To Axis.bVisible
    Function_Return Axis
  End_Function
  
  Procedure ConnectAxis
    String[] aParams
    Send ClientAction "connectAxis" aParams
  End_Procedure

  Procedure End_Construct_Object
    Forward Send End_Construct_Object
    Delegate Send RegisterAxis Self
  End_Procedure
End_Class