//TH-Header
//*****************************************************************************************
// Copyright (c)  2022 Antwise Solutions
// All rights reserved.
//
// $FileName    : SyncFusion\AppSrc\csfWebChartMarker.pkg
// $ProjectName : SyncFusion Library
// $Authors     : Wil van Antwerpen
// $Created     : 2022-12-30  15:50
//
// Contents:
//  This is used for determining how the marker looks like in the chart
//
// Documentation for the API is here:
// https://ej2.syncfusion.com/documentation/api/chart/markerSettings/
//
// Examples:
// https://ej2.syncfusion.com/javascript/documentation/chart/data-markers/
//
//
//*****************************************************************************************
//TH-RevisionStart
// ********************
// MODIFICATION SUMMARY
// ********************
// ####### DD/MM/YYYY  WHO COMMENT
//TH-RevisionEnd
Use csfWebChartChild.pkg
Use csfWebChartDataLabel.pkg

// https://ej2.syncfusion.com/documentation/api/chart/markerSettings/
Struct tsfWebChartMarkerSettings
  tsfWebChartBorderModel border
  tsfWebChartDataLabelSettings[] dataLabel  // as an array so that we can pass it as 0 items or 1 item
  String   sFill
  Integer  iHeight
  String   sImageURL
  Boolean  bIsFilled
  //tsfWebChartOffsetModel Offset
  Number   nOpacity
  String   sShape
  Boolean  bVisible
  Integer  iWidth
End_Struct


{ OverrideProperty=pbFillHeight Visibility=Private }
{ OverrideProperty=Auto_Fill_State Visibility=Private }
{ OverrideProperty=pbClearAfterSave Visibility=Private }
{ OverrideProperty=phoDataLabelSettings Visibility=Private }
{ DesignerJSClass=df.WebDesignerControl }
Class csfWebChartMarker Is a csfWebChartChild

  Procedure Construct_Object
    Forward Send Construct_Object
    
    // Options to customizing the border of the series.
    // This is applicable only for Column and Bar type series.
    //
    { WebProperty=Client }
    Property String  psBorderColor             ""
    // Set the width in pixels. If the width is -1 (C_WebDefault) then it will
    // use the default.
    { WebProperty=Client }
    Property Integer piBorderWidth             C_WebDefault
    // The fill color of the marker that accepts value in hex and rgba as a valid CSS color string.
    // By default, it will take series color.
    { WebProperty=Client }
    Property String  psFill                    ""
    // The height of the marker in pixels.
    // Defaults to 5
    { WebProperty=Client }
    Property Integer piHeight                  C_WebDefault
    // The URL for the Image that is to be displayed as a marker. It requires marker shape value
    // to be an Image.
    // Default is ""
    { WebProperty=Client }
    Property String  psImageUrl                ""
    // If set true, marker get filled with series color.
    // Default is false
    { WebProperty=Client }
    Property Boolean pbIsFilled                False
    // Set the opacity in a value between 0.0 and 1.0. If the width is -1 (C_WebDefault) then it will
    // use the default of 1.0
    { WebProperty=Client }
    Property Number  pnOpacity                 C_WebDefault
    // The different shape of a marker
    // The default is Circle
    { EnumList="Circle, Rectangle, Triangle, Diamond, HorizontalLine, VerticalLine, Pentagon, InvertedTriangle, Image" }
    { InitialValue="Circle" }
    { WebProperty=Client }
    Property String  psShape                   "Circle"
    // If set to true the marker for series is rendered. This is applicable only for line and area
    // type series.
    // Defaults to false
    { WebProperty=Client }
    Property Boolean pbVisible                 False
    // The width of the marker in pixels.
    // Defaults to 5
    { WebProperty=Client }
    Property Integer piWidth                   C_WebDefault
    
    // We set this to false, so we can detect if a DAW webcolumn was dropped
    // as it will have this set to true.
    Property Boolean pbIsWebColumn           False
    
    Property Handle  phoDataLabelSettings
    //
    Set psJSClass To "sf.WebChartMarker"
  End_Procedure
  
      
  Function LoadWebChartMarkerProperties Returns tsfWebChartMarkerSettings
    Handle hoDataLabel
    tsfWebChartMarkerSettings Marker
    tsfWebChartDataLabelSettings DataLabel
    
    Get psBorderColor       To Marker.border.sColor
    Get piBorderWidth       To Marker.border.iWidth
    Get psFill              To Marker.sFill
    Get piHeight            To Marker.iHeight
    Get psImageUrl          To Marker.sImageUrl
    Get pbIsFilled          To Marker.bIsFilled
    Get pnOpacity           To Marker.nOpacity
    Get psShape             To Marker.sShape
    Get pbVisible           To Marker.bVisible
    get piWidth             To Marker.iWidth
    Get phoDataLabelSettings   To hoDataLabel
    If (hoDataLabel<>0) Begin
      Move (ResizeArray(Marker.DataLabel,1)) To Marker.dataLabel
      Get LoadWebChartDataLabelProperties Of hoDataLabel To DataLabel
      Move DataLabel to Marker.dataLabel[0]
    End
    Function_Return Marker
  End_Function

  Procedure ConnectMarker
    Handle   hoDataLabel
    String[] aParams
    Send ClientAction "connectMarker" aParams
    Get phoDataLabelSettings   To hoDataLabel
    If (hoDataLabel<>0) Begin
      Send ConnectDataLabel To hoDataLabel
    End
  End_Procedure

  
  { Visibility=Private }
  Procedure RegisterDataLabelSettings Handle hoDataLabel
    If (hoDataLabel<>0) Begin
      Set phoDataLabelSettings to hoDataLabel
    End
  End_Procedure

  Procedure End_Construct_Object
    Forward Send End_Construct_Object
    Delegate Send RegisterMarkerSettings Self
  End_Procedure
End_Class