//TH-Header
//*****************************************************************************************
// Copyright (c)  2022 Antwise Solutions
// All rights reserved.
//
// $FileName    : SyncFusion\AppSrc\csfWebChartTooltip.pkg
// $ProjectName : SyncFusion Library
// $Authors     : Wil van Antwerpen
// $Created     : 2023-10-23  15:50
//
// Contents:
//  This is used for configuring the Chart Tooltip that you can use in a csfWebChart
//
// Documentation for the API is here:
// https://ej2.syncfusion.com/documentation/api/chart/tooltipSettingsModel/
//
//
//*****************************************************************************************
//TH-RevisionStart
// ********************
// MODIFICATION SUMMARY
// ********************
// ####### DD/MM/YYYY  WHO COMMENT
//TH-RevisionEnd
Use csfWebChartChild.pkg

// https://ej2.syncfusion.com/documentation/api/chart/tooltipSettingsModel/
Struct tsfWebChartTooltip
  tsfWebChartBorderModel border
  Integer iDuration
  Boolean bEnable
  Boolean bEnableAnimation
  Boolean bEnableMarker
  Boolean bEnableTextWrap
  Integer iFadeOutDuration
  String  sFadeOutMode
  String  sFill
  String  sFormat
  String  sHeader
  Number  nOpacity
  Boolean bShared
  Boolean bShowNearestPoint
  String  sTemplate
End_Struct


{ OverrideProperty=pbFillHeight Visibility=Private }
Class csfWebChartTooltip Is a csfWebChartChild

  Procedure Construct_Object
    Forward Send Construct_Object
    
    { WebProperty=Client }
    Property String  psBorderColor           ""
    
    // Set the width in pixels. If the width is -1 (C_WebDefault) then it will
    // use the default.
    { WebProperty=Client }
    Property Integer piBorderWidth           C_WebDefault

    // Duration for the ToolTip animation.
    { WebProperty=Client }
    Property Integer piDuration              C_WebDefault

    // Enables / Disables the visibility of the tooltip.
    { WebProperty=Client }
    Property Boolean pbEnable                True
    
    // If set to true, ToolTip will animate while moving from one point to another.
    { WebProperty=Client }
    Property Boolean pbEnableAnimation       False

    // Enables / Disables the visibility of the marker.
    { WebProperty=Client }
    Property Boolean pbEnableMarker          False

    // To wrap the tooltip long text based on available space. This is only application for chart tooltip.
    { WebProperty=Client }
    Property Boolean pbEnableTextWrap        False
    
    // Fade Out duration for the ToolTip hide.
    { WebProperty=Client }
    Property Integer piFadeOutDuration       C_WebDefault
    
    // Fade Out duration for the Tooltip hide.    
    { EnumList="Click, Move" }
    { WebProperty=Client }
    Property String  psFadeOutMode           ""

    // The fill color of the tooltip that accepts value in hex and rgba as a valid CSS color string.
    { WebProperty=Client }
    Property String  psFill                  ""

    // Format the ToolTip content.
    { WebProperty=Client }
    Property String  psFormat                ""

    // Header for tooltip. By default, the shared tooltip displays the point x value and 
    // the series name for each individual tooltip.    
    { WebProperty=Client }
    Property String  psHeader                ""

    // Set the opacity in a value between 0.0 and 1.0. If the width is -1 (C_WebDefault) then it will
    // use the default of 1.0
    { WebProperty=Client }
    Property Number  pnOpacity               C_WebDefault

    // If set to true, a single ToolTip will be displayed for every index.
    { WebProperty=Client }
    Property Boolean pbShared                False
    
    // By default, the nearest points will be included in the shared tooltip; however, you can 
    // set it to false to exclude the nearest value from the tooltip.
    { WebProperty=Client }
    Property Boolean pbShowNearestPoint      True
    
    // Custom template to format the ToolTip content. Use ${x} and ${y} as the placeholder text 
    // to display the corresponding data point.
    { WebProperty=Client }
    Property String  psTemplate              ""
    
    // We set this to false, so we can detect if a DAW webcolumn was dropped
    // as it will have this set to true.
    Property Boolean pbIsWebColumn           False
    //
    Set psJSClass To "sf.WebChartTooltip"
  End_Procedure
  
      
  Function LoadWebChartTooltipProperties Returns tsfWebChartTooltip
    tsfWebChartTooltip Tooltip
    Get psBorderColor     To Tooltip.border.sColor
    Get piBorderWidth     To Tooltip.border.iWidth
    Get piDuration        To Tooltip.iDuration
    Get pbEnable          To Tooltip.bEnable
    Get pbEnableAnimation To Tooltip.bEnableAnimation
    Get pbEnableMarker    To Tooltip.bEnableMarker
    Get pbEnableTextWrap  To Tooltip.bEnableTextWrap
    Get piFadeOutDuration To Tooltip.iFadeOutDuration
    Get psFadeOutMode     To Tooltip.sFadeOutMode
    Get psFill            To Tooltip.sFill
    Get psFormat          To Tooltip.sFormat
    Get psHeader          To Tooltip.sHeader
    Get pnOpacity         To Tooltip.nOpacity
    Get pbShared          To Tooltip.bShared
    Get pbShowNearestPoint To Tooltip.bShowNearestPoint
    Get psTemplate        To Tooltip.sTemplate
    Function_Return Tooltip
  End_Function
  
  Procedure ConnectTooltip
    String[] aParams
    Send ClientAction "connectTooltip" aParams
  End_Procedure

  Procedure End_Construct_Object
    Forward Send End_Construct_Object
    Delegate Send RegisterTooltip Self
  End_Procedure
End_Class