//TH-Header
//*****************************************************************************************
// Copyright (c)  2020 PP7
// All rights reserved.
//
// $FileName    : csfWebColumnAggregate.pkg
// $ProjectName : PP7 SyncFusion
// $Authors     : Wil van Antwerpen, Sergey Natarov
// $Created     : 06.04.2020  13:46
//
// Contents:
// This is a web framework wrapper class for the SyncFusion Grid control.
// Documentation for the API is here:
// https://ej2.syncfusion.com/documentation/api/grid
//
//*****************************************************************************************
//TH-RevisionStart
// ********************
// MODIFICATION SUMMARY
// ********************
// ####### DD/MM/YYYY  WHO COMMENT
//TH-RevisionEnd

Use csfWebColumn_Mixin.pkg

Class csfWebColumnAggregate Is a cObject
    Procedure Construct_Object
        Forward Send Construct_Object
        { DesignTime=False }
        Property Integer piAggregateId -1 // will be assigned when the grid is registered below
        //
        Send Define_csfWebColumn_Mixin
        //
        { Visibility=Private }
        Property Integer private_Data_File 0    // The binding table
        { Visibility=Private }
        Property Integer private_Data_Field 0   // The binding table column
        //
        { EnumList="Sum, Average, Max, Min, Count, TrueCount, FalseCount, Custom" }
        { InitialValue="" }
        Property String  psType
        { EnumList="C0, C2, P0, P2, N0, N2" }
        { InitialValue="" }
        Property String  psFormat
        Property String  psFooterTemplate
        Property String  psGroupFooterTemplate
    End_Procedure

    Import_Class_Protocol csfWebColumn_Mixin
    
    // this will be sent by the Entry_item command
    { Visibility=Private }
    Procedure Bind_Data Integer iFile Integer iField
        Set Data_File to iFile
        Set Data_Field to iField
    End_Procedure

    { MethodType=Property }
    { DesignTime=False }
    { ItemParameter=1 }
    Procedure Set Data_File Integer iItem Integer iFile
        Set private_Data_File to iFile
    End_Procedure
    
    { MethodType=Property }
    { DesignTime=False }
    { ItemParameter=1 }
    Procedure Set Data_Field Integer iItem Integer iField
        Set private_Data_Field to iField
    End_Procedure
    
    { MethodType=Property }
    { DesignTime=False }
    { ItemParameter=1 }
    Function Data_File Integer iItem Returns Integer
        Function_Return (private_Data_File(Self))
    End_Function
    
    { MethodType=Property }
    { DesignTime=False }
    { ItemParameter=1 }
    Function Data_Field Integer iItem Returns Integer
        Function_Return (private_Data_Field(Self))
    End_Function

    Procedure End_Construct_Object
        Forward Send End_Construct_Object
        Send BuildColumnID
        Delegate Send RegisterColumnAggregate Self
    End_Procedure
End_Class