Use Dfclient.pkg

Cd_Popup_Object oNewLanguage Is a dbModalPanel
    Set pbSizeToClientArea to False
    Property Integer Invoking_Object_ID        0
    Set Label To "Create New Language"
    Set Size To 58 187
    Set Location To 6 79
    Set Border_Style To Border_Dialog
    Object oLanguage Is a Form
        Set Label To "Language name:"
        Set Size To 13 108
        Set Location To 5 68
    End_Object    // oLang
    Object oOK Is a Button
        Set Label To "&OK"
        Set Location To 23 68
        Procedure OnClick
            Send mNewLanguage
        End_Procedure
    End_Object    // oOK
    Object oCancel Is a Button
        Set Label To "&Cancel"
        Set Location To 23 126
        Procedure OnClick
            Send Close_Panel
        End_Procedure
    End_Object    // oCancel
    Procedure mNewLanguage
        String  sLanguage
        Integer iObj iC iRet
        Get Invoking_Object_ID to iObj
        Get Value of (oLanguage(Current_Object)) item 0 to sLanguage
        If ((iObj)and(sLanguage<>"")) Begin
            Get FindLanguage of ghoEditorProperties sLanguage to iC
            If (iC<0) Begin
                Get YesNo_Box (_T("Do you wish to create a new language definition?", 1514)) (_T("Confirmation", 1515)) MBR_YES to iRet
                If (iRet<>MBR_Yes) Begin
                    Send Close_Panel
                End
                Else Begin
                    Send Combo_Add_Item of iObj sLanguage
                    Set Value           of iObj item 0 to sLanguage
                    Send OnChange       to iObj
                End
            End
        End
        Send Close_Panel
    End_Procedure
    Procedure Popup
        Set Invoking_Object_ID To (Focus(Desktop))
        Forward Send Popup
    End_Procedure

    #IFDEF TH_TRANSLATION
    Procedure Translate
        Set Label               to gILanguage[1510]
        Set Label of oLanguage  to gILanguage[1511]
        Set Label of oOK        to gILanguage[1512]
        Set Label of oCancel    to gILanguage[1513]
    End_Procedure
    #ENDIF

    Procedure Activating
        Forward Send Activating
        #IFDEF TH_TRANSLATION
        Send Translate
        #ENDIF
    End_Procedure

Cd_End_Object    // oNewLanguage