Use cProcessStatusPanel.pkg
Use cStatusProgressBar.pkg
Use Windows.pkg

Global_Variable Handle ghoCallbackProgressBar

Register_Object hoved

Object oUpdateStatusPanel is a cProcessStatusPanel
    Set Location to 28 33

    Set Size to 69 317
    Set Caption_text to "(autotext)"

    Object oStatusTekst is a TextBox
        Set Auto_Size_State to False
        Set Size to 10 279
        Set Location to 5 17
        Set Label to '(status)'
    End_Object
    
    Object Textbox2 is a Textbox
        Set Label to "File progress:"
        Set Location to 36 16
        Set Size to 10 41
    End_Object
    
    Object oFileprogressPB is a cStatusProgressBar
        Set piAdvanceBy to 1
        Set Location to 22 62
        Set Size to 19 233
        Set pbSmooth to True
    End_Object

    Object oCallbackPB is a cStatusProgressBar
        
        Move Self to ghoCallbackProgressBar

        Function CallBack String callback_msg Integer callback_type Returns Integer
            Integer val1 val2 iCommaPos iCurrentpos
            Number nOffset
            Trim callback_msg to callback_msg
            If (Callback_type = DF_MESSAGE_PROGRESS_VALUE) Begin
                Pos "," in callback_msg to iCommaPos
                Left callback_msg to val1 (iCommaPos -1)
                Right callback_msg to val2 (Length(callback_msg)-iCommaPos)
                calc (val2 / 100) to nOffset
                Calc (val1 / nOffset) to iCurrentpos
                Set piPosition to iCurrentpos
            End
            Else Begin
                Send skriv of hoved callback_msg
                Set piPosition to 0
            End
            Function_Return False   // Continue the process
        End_Function

        Set piAdvanceBy to 1
        Set Location to 43 62
        Set Size to 6 233
        Set pbSmooth to True

    End_Object    // pCallback
   
    object oStopButton is a Button
        Set Location to 52 133
        Set Label to C_$Cancel
        
        procedure OnClick
            send Close_panel
        end_procedure
    
    end_object

    // These messages bind the standard cProcessStatusPanel interface to the actual
    // objects defined within this instance of the status panel.
    


    // gets called when status panel is activated passing whether a button
    // should appear
    Procedure EnableCancelButton boolean bEnable
        Set Enabled_State of oStopButton to bEnable
    End_Procedure
    
    // If any values are -1 it is not applied.
    Procedure FileprogresseStatus Integer iMin Integer iMax Integer iProgress
        Set piMinimum of oFileprogressPB to iMin
        Set piMaximum of oFileprogressPB to iMax
        Set piPosition of oFileprogressPB to iProgress
    End_Procedure
    
    // If any values are -1 it is not applied.
    Procedure CallbackStatus Integer iMin Integer iMax Integer iProgress
        Set piMinimum of oCallbackPB to iMin
        Set piMaximum of oCallbackPB to iMax
        Set piPosition of oCallbackPB to iProgress
    End_Procedure
    
    Procedure MaxAllPB
        Integer iMax
        Get piMaximum of oFileprogressPB to iMax
        Set piPosition of oFileprogressPB to iMax
        Get piMaximum of oCallbackPB to iMax
        Set piPosition of oCallbackPB to iMax
    End_Procedure
    
    Procedure ClearAllPB
        Set piPosition of oCallbackPB to 0
        Set piPosition of oFileprogressPB to 0
        Set Statustekst to ""
    End_Procedure
    
    Procedure Set Statustekst String sTekst
        Set Label of oStatusTekst to sTekst
        Send ProcessEvents
    End_Procedure

End_Object